Unprotecting Groups of Worksheets

Excel allows you to protect and unprotect worksheets. The purpose, of course, is to allow others to use your workbook, but not to modify certain cells within each worksheet.

Since protection is done at a worksheet level, it can be major pain to step through each worksheet in a workbook and either protect or unprotect them. If you have 25 worksheets, you must activate each worksheet, do the protect or unprotect, and move on to the next one.

A less time-consuming method of protecting each worksheet in a workbook is to use a macro to do the actual work. The following macro will do the trick:

Sub ProtectAllSheets()
    Dim ws As Worksheet
    Dim sOrigSheet As String
    Dim sOrigCell As String

    Application.ScreenUpdating = False
    sOrigSheet = ActiveSheet.Name
    sOrigCell = ActiveCell.Address

    For Each ws In Worksheets
        ws.Select
        ws.Protect Password:="Password"
    Next ws

    Application.GoTo Reference:=Worksheets("" _
      & sOrigSheet & "").Range("" & sOrigCell & "")
    Application.ScreenUpdating = True
End Sub

The macro to unprotect all the worksheets is only slightly different:

Sub UnProtectAllSheets()
    Dim ws As Worksheet
    Dim sOrigSheet As String
    Dim sOrigCell As String

    Application.ScreenUpdating = False
    sOrigSheet = ActiveSheet.Name
    sOrigCell = ActiveCell.Address

    For Each ws In Worksheets
        ws.Select
        ws.Unprotect Password:="Password"
    Next ws

    Application.GoTo Reference:=Worksheets("" _
      & sOrigSheet & "").Range("" & sOrigCell & "")
    Application.ScreenUpdating = True
End Sub

While these macros will work just fine, there are a couple of caveats. First, you need to make sure that the Password variable in each macro is set to the proper password for your worksheets. (This assumes, of course, that all the worksheets use the same passwords.) The second caveat is that since the macro has to include the password, the overall security of your workbook may be compromised—anyone that can display the macros will know what the passwords are for your workbooks.

As a solution to this last problem, you could modify the macros so that they ask for a password to use in their work. The following would be the version of the macro that protects worksheets:

Sub ProtectAllSheetsPass()
    Dim ws As Worksheet
    Dim sOrigSheet As String
    Dim sOrigCell As String
    Dim sPWord As String

    Application.ScreenUpdating = False
    sOrigSheet = ActiveSheet.Name
    sOrigCell = ActiveCell.Address

    sPWord = InputBox("What password?", "Protect All")
    If sPWord > "" Then
        For Each ws In Worksheets
            ws.Select
            ws.Protect Password:=sPWord
        Next ws
    End If
    Application.GoTo Reference:=Worksheets("" _
      & sOrigSheet & "").Range("" & sOrigCell & "")
    Application.ScreenUpdating = True
End Sub

The macro displays an input box asking for the password. The same password is then used to protect every worksheet in the workbook. The same sort of change can be done to the macro that unprotects all the worksheets.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13075) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and Excel in Microsoft 365. You can find a version of this tip for the older menu interface of Excel here: Unprotecting Groups of Worksheets.