Searching for All

Jack wonders how he can do a search for a certain word or phrase and, in one step, highlight all the cells containing it so that he can cut or copy them and paste them elsewhere.

Selecting the cells containing the text you want to use is rather easy; you can use the standard Find and Replace feature to do it. Follow these steps:

1. Press Ctrl+F. Excel displays the Find tab of the Find and Replace dialog box.
2. Expand the dialog box by clicking the Options button. (See Figure 1.)



Figure 1. The Find tab of the Find and Replace dialog box.

3. In the Find What box, enter the text you want to find.
4. Use the controls in the dialog box to limit the matches, as desired.
5. Click Find All. The dialog box is expanded to show all the matches that were located.
6. Press Ctrl+A. This selects all those cells that were found.
7. Click Close to dismiss the dialog box.

That's it. As long as you didn't click on Match Entire Cell Contents in step 4, Excel selects all the cells that contain the text you specified in step 3. You can, at that point, apply formatting to the cells, if desired.

You could, of course, use conditional formatting to dynamically format cells that contain the text you want to highlight. All you need to do is set up a condition that uses "Text Contains" as the test. This won't, of course, select all the cells that contain the text, but it will highlight them so you can pick out where they are.

You could also use a macro to select all the cells that contain the desired text. The following is a rather simple one that accomplishes the task:

Sub selCellbasedonValue()
    Dim c As Object
    Dim u As Range
    Dim v As Range
    Dim sInpt As String

    Set u = ActiveSheet.UsedRange

    sInpt = InputBox("Enter the search text")

    If sInpt > "" Then
        For Each c In u
            If Instr(LCase(sInpt),LCase(c.Value)) > 0 Then
                If v Is Nothing Then
                    Set v = Range(c.Address)
                Else
                    Set v = Union(v, Range(c.Address))
                End If
            End If
        Next
        v.Select
        Set v = Nothing
    End If

    Set u = Nothing
End Sub

There is a problem with selecting cells that you need to recognize, however—if the cells are non-contiguous, you cannot cut or copy the cells. If you try, you'll get an error message indicating that the command cannot be used on multiple selections. The easiest way to copy cell contents to a different location is to, again, use a macro:

Sub CopyFinds()
    Dim sSrch As String
    Dim sFirst As String
    Dim rPaste As Range
    Dim i As Integer
    Dim iLeftC As Integer
    Dim lTopR As Long
    Dim c As Object

    If Selection.Cells.Count = 1 Then
        MsgBox "Select the range to be searched."
        Exit Sub
    End If

    'Specify search string
    sSrch = InputBox(Prompt:="Enter the search text")

'   Set the paste address
    On Error Resume Next
    Set rPaste = Application.InputBox(Prompt:="Enter the upper-left " & _
      "cell address for the paste range", Type:=8)
    On Error GoTo 0

'   Exit if canceled
    If TypeName(rPaste) <> "Range" Then Exit Sub

'   Upper left cell to be used
    Set rPaste = rPaste.Range("A1")

    'Set where paste will start and headings
    Application.ScreenUpdating = False
    lTopR = rPaste.Row
    iLeftC = rPaste.Column
    Cells(lTopR, iLeftC) = "Address"
    Cells(lTopR, iLeftC + 1) = "Cell Value"
    lTopR = lTopR + 1
    
    'Start copying cell values
    With Selection
        Set c = .Find(What:=sSrch, LookAt:=xlPart, MatchCase:=True)
        If Not c Is Nothing Then
            sFirst = c.Address
            Do
                Cells(lTopR, iLeftC) = c.Address
                Cells(lTopR, iLeftC + 1) = c.Value
                Set c = .FindNext(c)
                lTopR = lTopR + 1
            Loop While Not c Is Nothing And c.Address <> sFirst
        End If
    End With
    
    Application.ScreenUpdating = True
    Cells(rPaste.Row, rPaste.Column).Select
End Sub

When you select a range of cells and run this macro, you are asked to specify what you are searching for (case is important) and an address of where you want to copy it. The macro then finds all cells that contain that value and copies both their address and the cell value to the starting address you specified. The macro doesn't do a lot of error checking; it will overwrite information if you specify a target address that has information in it already. In addition, if you specify a target address that is within the range you are searching, the macro may run infinitely. You should definitely specify a target that is outside of the range being searched.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (8964) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and Excel in Microsoft 365. You can find a version of this tip for the older menu interface of Excel here: Searching for All.