Magnifying Only the Current Cell

Brian asked if there is a way in Excel to magnify the contents of the current cell. He's working on a worksheet which needs to be at a low zoom setting (30% or so) to see the whole sheet. As different scenarios are run, cells change color depending on the result. Brian can easily see which cells he needs to investigate, but he can't read them because of the zoom setting. He normally changes the zoom, reads the answer, and zooms back out to run another scenario. It would be much easier if only the current cell (the one selected) were magnified to a readable level.

There is no built-in method in Excel to accomplish this selective method of zooming, but the Magnifier (an Ease of Access tool provided in Windows) may do just what Brian wants. The program magnifies the area near the mouse pointer, overlaying another area of the screen with the enlarged image. You can kick the Magnifier tool into gear by holding down the Windows key (the one that has the Windows logo on it) and pressing the + key on the numeric keypad. The screen is magnfied. Press the Windows key again and then the Ð (minus) key and the screen goes back to normal. You can find out more information about the Magnifier in this WindowsTip:

https://tips.net/T12562

If you are bound and determined to do the magnification within Excel, there are a couple of workarounds you can try. One such workaround is to use a macro that displays the value in the active cell in a message box. Such a macro is easy to add to the worksheet module:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    MsgBox ActiveCell.Address & ": " & ActiveCell.Value
End Sub

Every time you select a different cell in the worksheet, the macro pops up a message box that shows the contents of that cell. This solves the problem, but it can get tiresome to continually close message boxes every time you change which cell is selected.

You could also create a macro that simply changed the font size of whatever cell is currently selected. The following simple macro, added to the worksheet module, looks at the currently selected cell and increases its font size by 500%.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    FontSize = ActiveCell.Font.Size
    LargeSize = FontSize * 5
    Cells.Font.Size = FontSize
    ActiveCell.Font.Size = LargeSize
End Sub

The utility of such a macro will depend, of course, on how you have the height and width of the selected cell formatted. If they are static heights and widths, it is possible that increasing the font size will make the cell contents unreadable. If the height and width are dynamic, then the contents should still be quite readable.

Still another approach is to create your own zoomed-in picture of each cell as it is selected:

Private Sub ZoomCell(ZoomIn As Single)
    Dim s As Range
    Set s = Selection

    'Get rid of any existing zoom pictures
    For Each p In ActiveSheet.Pictures
        If p.Name = "ZoomCell" Then
            p.Delete
            Exit For
        End If
    Next

    'Create a zoom picture
    s.CopyPicture Appearance:=xlScreen, _
      Format:=xlPicture
    ActiveSheet.Pictures.Paste.Select
    With Selection
        .Name = "ZoomCell"
        With .ShapeRange
            .ScaleWidth ZoomIn, msoFalse, _
              msoScaleFromTopLeft
            .ScaleHeight ZoomIn, msoFalse, _
              msoScaleFromTopLeft
            With .Fill
                .ForeColor.SchemeColor = 9
                .Visible = msoTrue
                .Solid
            End With
        End With
    End With
    s.Select
    Set s = Nothing
End Sub

In order to use the macro, you need to call it each time the selection in the worksheet changes. To do this, you add a small macro to the worksheet module:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    ZoomCell 6
End Sub

In this case, every time the cell selection is changed, the ZoomCell macro is run to create a picture that is six times the size of the original. If it gets bothersome to have the picture automatically change every time you select a different cell, you could do away with the trigger macro in the worksheet module and modify the ZoomCell macro so that it runs whenever you initiate it, perhaps with a shortcut key that you set up.

Sub ZoomCell()
    Dim s As Range
    Dim ZoomIn As Single
    Set s = Selection
    ZoomIn = 6

    'Get rid of any existing zoom pictures
    For Each p In ActiveSheet.Pictures
        If p.Name = "ZoomCell" Then
            p.Delete
            Exit For
        End If
    Next

    'Create a zoom picture
    s.CopyPicture Appearance:=xlScreen, _
      Format:=xlPicture
    ActiveSheet.Pictures.Paste.Select
    With Selection
        .Name = "ZoomCell"
        With .ShapeRange
            .ScaleWidth ZoomIn, msoFalse, _
              msoScaleFromTopLeft
            .ScaleHeight ZoomIn, msoFalse, _
              msoScaleFromTopLeft
            With .Fill
                .ForeColor.SchemeColor = 9
                .Visible = msoTrue
                .Solid
            End With
        End With
    End With
    s.Select
    Set s = Nothing
End Sub

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10426) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, Excel in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Excel here: Magnifying Only the Current Cell.