Please Note: This article is written for users of the following Microsoft Excel versions: 2007, 2010, and 2013. If you are using an earlier version (Excel 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Excel, click here: Changing Font Face and Size Conditionally.

Changing Font Face and Size Conditionally

by Allen Wyatt
(last updated September 28, 2018)

2

Robin asks if there is a way to use Excel's conditional formatting capabilities to change the font use in a cell or to change the font size in a cell. The short answer is no, that can't be done—at least not with conditional formatting. (The controls that allow you to specify font name and size are grayed-out in the formatting dialog box used with conditional formatting.)

You can, however, use a macro to examine cell contents and make changes in the appearance of a cell. Consider the following macro, which examines any cells you have selected when you run the macro. If any of the cells have a length of more than two characters or a value of more than 10, then the cell's font is changed.

Sub DoReformat()
    Dim rCell As Range

    For Each rCell In Selection.Cells
        If Len(rCell.Text) > 2 Or _
          Val(rCell.Value) > 10 Then
            rCell.Font.Name = "Arial"
            rCell.Font.Size = 16
        Else
            rCell.Font.Name = "Times New Roman"
            rCell.Font.Size = 12
        End If
    Next
End Sub

To use the macro, just select the cells you want changed and then run the macro. If you want the formatting to change more automatically, then you can have the macro check to see if a change was made within a certain range of cells:

Private Sub Worksheet_Calculate()
    Dim rng As Range
    Dim rCell As Range

    Set rng = Range("A1:A10")

    For Each rCell In rng
        If Len(rCell.Text) > 2 Or _
          Val(rCell.Value) > 10 Then
            rCell.Font.Name = "Arial"
            rCell.Font.Size = 16
        Else
            rCell.Font.Name = "Times New Roman"
            rCell.Font.Size = 12
        End If
    Next
End Sub

This macro, when added to the worksheet object, will run every time the worksheet is recalculated. It checks the range A1:A10, applying the same tests as in the previous macro. The result is that the formatting of the cells is checked and changed continuously. To have the macro check a different range, just change the addresses assigned to the rng variable near the beginning of the macro.

One drawback of this macro is that it can get sluggish if you have a very large range for it to check. It will go very quickly if you are checking A1:A10 (ten cells), but may go much slower if you are continually checking B2:N465 (over 6,000 cells). In that case, you may want to design the macro so it runs whenever the worksheet is changed, but only takes action if the change was done to a cell in your target range. The following version is also added to the worksheet object:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rCell As Range

    If Union(Target, Range("A1:A10")).Address = _
      Range("A1:A10").Address Then
        Application.EnableEvents = False
        For Each rCell In Target
            If Len(rCell.Text) > 2 Or _
              Val(rCell.Value) > 10 Then
                rCell.Font.Name = "Arial"
                rCell.Font.Size = 16
            Else
                rCell.Font.Name = "Times New Roman"
                rCell.Font.Size = 12
            End If
        Next
        Application.EnableEvents = True
    End If
End Sub

The macro uses the Union function to check whether the cells changed (passed to the event handler in the Target variable) have any overlap with the range you want checked. If they do, then the checking is done on the cells in the Target range.

One thing to keep in mind with macros that affect formatting is that if you have conditional formatting applied to a cell that is also checked by a macro, the formatting in the conditional formatting takes precedence over the formatting in the macro. If your macro is changing font name and font size, this isn't a big concern because conditional formatting won't affect these attributes. However, if you change your macro to also change a different format attribute—such as cell color—and that attribute is also changed by the conditional format, then it won't look like the macro did anything because Excel uses the conditional formatting in preference to what the macro does.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the ExcelTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13236) applies to Microsoft Excel 2007, 2010, and 2013. You can find a version of this tip for the older menu interface of Excel here: Changing Font Face and Size Conditionally.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Opening Only a Merge Document

After merging the information from a data source into a document, you may decide that you only want to open the merge ...

Discover More

Copying Comments when Filtering

The filtering feature in Excel allows you to quickly copy unique information from one data list to another. If you want ...

Discover More

Finding Text at the End of a Table Cell

How do you use Find and Replace to locate information at the end of a table cell? Interestingly enough, there is no way ...

Discover More

Excel Smarts for Beginners! Featuring the friendly and trusted For Dummies style, this popular guide shows beginners how to get up and running with Excel while also helping more experienced users get comfortable with the newest features. Check out Excel 2013 For Dummies today!

More ExcelTips (ribbon)

Conditionally Formatting an Entire Row

Need to conditionally highlight an entire row based on the contents of a single cell in each row? This tip explains how ...

Discover More

Highlighting Cells Containing Specific Text

If you want to highlight cells that contain certain characters, you can use the conditional formatting features of Excel ...

Discover More

Working with Multiple Conditions

When you apply conditional formatting, you are not limited to using a single condition. Indeed, you can set up multiple ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 3 + 4?

2018-04-26 15:03:30

Richard Matt

First: Thank you for a very nicely written , relevant post.

Second: I tried to subscribe to your newsletter, but my e-mail address was not accepted.

Third: I am an experienced programmer, but have never used an Excel macro, so the root of my problem is probably something trivial.

By looking up other webpages on how to save a macro into an Excel file, I was able to get the first macro on this webpage to work properly when I clicked on the 'Run' button.

When I repeated the same steps with the second macro on this webpage, it would run successfully when I clicked on the 'Run' button; however, I understood that the object of this macro was that it would run automatically. (Well . . . it would run when the Excel spreadsheet recalculates, and I verified that the spreadsheet was set-up so it recalculated automatically.)

Can you tell me a few likely reasons (or things to check) for the second macro to update the format as soon as the cell content changes?


2014-10-06 12:37:37

Alex

This was very helpful. One further question though: is there code that will format the size of text in a range based on the values a different or neighboring range? Thanks.


This Site

Got a version of Excel that uses the ribbon interface (Excel 2007 or later)? This site is for you! If you use an earlier version of Excel, visit our ExcelTips site focusing on the menu interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.