Replacing Characters at the End of a Cell

Re. RTrim, LTrim, and Trim discussed in earlier comments below, My Excel Toolbox now includes the following functions useful in cell formulas:
=TrimHead(Text,[NumChars])
=TrimTail(Text,[NumChars])
TrimHead trims leading characters from Text and returns the result. If optional NumChars < 1 (default), all leading space characters are trimmed; otherwise, NumChars leading text characters are trimmed.
TrimTail is analogous except it trims trailing characters.
Here are abbreviated versions:

Function TrimHead(Text As String, Optional NumChars As Integer) As String
    If NumChars < 1 Then
        TrimHead = LTrim(Text)
    Else
        TrimHead = Mid(Text, (NumChars + 1))
    End If
End Function

Function TrimTail(Text As String, Optional NumChars As Integer) As String
    If NumChars < 1 Then
        TrimTail = RTrim(Text)
    Else
        Dim n As Integer
        n = Len(Text) - NumChars
        If n > 0 Then TrimTail = Left(Text, n) 'else return null default
    End If
End Function

See https://sites.google.com/view/MyExcelToolbox/

@Willy Vanhaelen
I forgot about RTrim. I should have used it. Thank you for reminding me.
Curiously, RTrim and Trim are difficult to find alphabetically in Microsoft's VBA documents because they are listed with LTrim (i.e., "LTrim, RTrim, and Trim").
See https://learn.microsoft.com/en-us/office/vba/language/reference/functions-visual-basic-for-applications

@J. Woolley
Your macro is a well thought out work piece. I wonder though if you have a special reason to use a Do While Loop to remove trailing spaces (if any) instead of the RTrim function?

Adding the .SpecialCells(xlCellTypeConstants, xlTextValues) to Selection in my macro would make it more robust .

@Peter Atherton
Adding C = RTrim(C) would also make my macro more robust.

Willy's version is very clever. Here is my version. It's a little more robust and accommodates hyphenated directions like N-E.
For all text constants in Selection, capitalize the last word after deleting any hyphens if it represents one of 16 points on the compass:

Sub CapDirections3()
    Dim rCell As Range, sComp() As String, sText As String, sTemp As String
    Dim nChar As Integer, n As Integer
    sComp = Split("N NNE NE ENE E ESE SE SSE S SSW SW WSW W WNW NW NNW")
    For Each rCell In Selection.SpecialCells(xlCellTypeConstants, xlTextValues)
        sText = rCell.Value
        Do While Right(sText, 1) = " "
            sText = Left(sText, (Len(sText) - 1))
        Loop
        nChar = InStrRev(sText, " ")
        sTemp = UCase(Replace(Mid(sText, (nChar + 1)), "-", ""))
        For n = 0 To 15
            If sTemp = sComp(n) Then
                rCell.Value = Left(sText, nChar) + sTemp
                Exit For
            End If
        Next n
    Next rCell
End Sub

Willy, Nice one but I'd add a line to deal with Allen's point about typos

For Each C In Selection
C = Trim(C)

The macro in this tip does a fine job but my version hereafter uses a different approach and is a bit simpler:

Sub CapDirections2()
Dim C As Range
For Each C In Selection
    If InStr(" ne se sw nw", Right(C, 3)) Then
        C = Replace(C, Right(C, 2), UCase(Right(C, 2)))
    End If
Next C
End Sub

The code is almost self explanatory:

IF the 3 last characters in the cell are found in the string being searched THEN
    Replace the utmost 2 characters of the cell by there upper case ones
END IF

That's it :-)