Accepting Only a Single Digit

If you really want to use the single digit technique described in the Tip and implemented in my earliest comment below, perhaps there would be less trouble if you restrict it to the numeric keypad in combination with the Ctrl key, for example. In this case, modify the Assigns macro in my first comment as follows:

Sub Assigns()
Dim i As Integer, proc As String, key As String
For i = 0 To 9
proc = "'Dig(" & i & ")'" 'apostrophes are necessary
key = "^{" & (96 + i) & "}" 'Ctrl+numeral on numeric keypad
Application.OnKey key, proc
Next i
End Sub

Then make a similar change to the ClearAssigns macro. Notice the caret (^) represents the Ctrl key.

@Willy Vanhaelen
In my previous comment I said, "Also, the Tip's Assigns macro does not work as expected because OnKey expects text parameters." Now I believe the original macro's problem can be resolved by replacing this statement
.OnKey i, "dig" & i
with the following statement
.OnKey i, "'dig" & i & "'"
Although not mentioned in Microsoft's document, it is important to surround the OnKey procedure with apostrophes.

The Tip's ten dig# macros have a common issue: To select the "next cell to the right" (instead of down), replace this statement
    ActiveCell.Offset(1, 0).Select
with the following statement
    ActiveCell.Offset(0, 1).Select
Also, the Tip's Assigns macro does not work as expected because OnKey expects text parameters. Finally, the ten OnKey events addressed by the Tip's Assigns and ClearAssigns macros only apply to numerals above the alpha keys on the keyboard, not to numerals on the numeric keypad.
Here's an improved version of the Tip's macros with 12 procedures replaced by 3 servicing 20 OnKey events (counting the numeric keypad):

Sub Assigns()
    Dim i As Integer, proc As String, key As String
    For i = 0 To 9
        proc = "'Dig(" & i & ")'" 'apostrophes are necessary
        key = i 'numeral above alpha keys
        Application.OnKey key, proc
        key = "{" & (96 + i) & "}" 'numeral on numeric keypad
        Application.OnKey key, proc
    Next i
End Sub

Sub ClearAssigns()
    Dim i As Integer, key As String
    For i = 0 To 9
        key = i 'numeral above alpha keys
        Application.OnKey key
        key = "{" & (96 + i) & "}" 'numeral on numeric keypad
        Application.OnKey key
    Next
End Sub

Sub Dig(arg As Byte)
    ActiveCell.Value = arg
    ActiveCell.Offset(0, 1).Select
End Sub

Although not mentioned in Microsoft's document, the OnKey procedure should be surrounded by apostrophes for reliable results.

I have an application where I could use the OnKeys macros. So I tested the macros of this tip but they don't do the job. I get the following error:
(see Figure 1 below)
So I started to experiment because at first sight there is nothing wrong with the macros and normally they should work. Finally I found the reason of the error but I can't explain it. Examining the "View Macros box" (Alt+F8) revealed that only the macro dig0 can be executed. The dig1 till dig9 macros are greyed out (disabled). After some trials I got it finally to work by changing the line of code in the For Next loop in the Assigns macro to:
.OnKey i, "Module1.dig" & i
and this works.

So only the first run of the For Next loop is executed and the 9 other runs are ignored. WEIRD !!!

I use Windows 10 and Excel 2019 but I tested it on my laptop with Windows 7 and Excel 2007 with the same result. So it seems to be general except perhaps in versions of Excel prior to 2007. Obviously these macros were not tested again before the tip was published in this week's (10 jun) Excel Tips (ribbon) :-(