Doing Math Using Roman Numerals

Ian has two cells (A1 and A2) in which he has Roman numerals. He would like to subtract A2 from A1, but doesn't know how to put together a formula to do it without using helper columns. Ian wonders if there is a way he can use a single formula.

The short answer is yes, this can be done. The key is to remember that Roman numerals are not numeric, but are considered text by Excel. So, before you can do any math with them, you need to convert them from their text values to numbers. Excel provides the ARABIC function to convert a Roman number to decimal, and the function returns just that—a number that you can use for math.

So, to subtract A2 from A1, you could use this formula:

=ARABIC(A1)-ARABIC(A2)

This returns a decimal value. If you want, instead, to see the result as Roman numerals, you can wrap the formula in the ROMAN function, as shown here:

=ROMAN(ARABIC(A1)-ARABIC(A2))

Understand that if your subtraction produces a negative result, then the ROMAN function will return a #VALUE! error because there is no way to represent negative values using Roman numerals. In addition, the ROMAN function will not handle a value above 3,999, but the ARABIC function will. (Go figure!)

Finally, you should be aware that the ARABIC function was introduced in Excel 2013, so if you are still using Excel 2007 or Excel 2010, you'll be out of luck. In that case, you could try a different approach, such as the following ingenious formula:

=MATCH(A1,INDEX(ROMAN(ROW(INDIRECT("1:3999"))),0),0)-
MATCH(A2,INDEX(ROMAN(ROW(INDIRECT("1:3999"))),0 ),0)

The formula converts row numbers into Roman numerals and then finds out which one matches the text that is in the cells. It produces a result in regular decimal notation. If you want it in Roman numerals, instead, then you'll need to wrap it in the ROMAN function:

=ROMAN(MATCH(A1,INDEX(ROMAN(ROW(INDIRECT("1:3999"))),0),0)-
MATCH(A2,INDEX(ROMAN(ROW(INDIRECT("1:3999"))),0 ),0))

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (2698) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, Excel in Microsoft 365, and 2021.