Please Note: This article is written for users of the following Microsoft Excel versions: 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Excel in Microsoft 365. If you are using an earlier version (Excel 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Excel, click here: Finding the Dates for Minimums and Maximums.
Written by Allen Wyatt (last updated October 9, 2025)
This tip applies to Excel 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Excel in Microsoft 365
Michael has some data in two columns of a worksheet. Column A is a series of dates and column B contains expenditures for each of those dates. He needs a way to determine the date on which the minimum expenditure occurred and a way to find the date on which the maximum expenditure occurred.
If you are using Excel 2021, 2024, or Microsoft 365, you can use the XLOOKUP function to get the dates of the desired minimum and maximum expenditures:
=XLOOKUP(MIN(B:B),B:B,A:A) =XLOOKUP(MAX(B:B),B:B,A:A)If you are using an older version of Excel, you might be tempted to think you could use VLOOKUP to figure out the desired dates. Unfortunately, that won't work because VLOOKUP keys off of whatever data is in the first column of your data table. Since you want to key off of the amount (looking for the minimum and maximum), you would need to switch the position of the columns, so that column A contained the amount and column B contained the dates. If you do that, you could then use the following formulas to find the dates for the minimum and maximum expenditures, respectively:
=VLOOKUP(MIN(A:A),A:B,2,0) =VLOOKUP(MAX(A:A),A:B,2,0)
If you cannot change the data columns, then you'll need to forego VLOOKUP and use a different approach, instead. The following two formulas will work with the data as originally specified by Michael:
=INDEX(A:A,MATCH(MIN(B:B),B:B,0)) =INDEX(A:A,MATCH(MAX(B:B),B:B,0))
It is important to note that if there are duplicates of the maximum and/or minimum expenditures, these formulas will only find the dates of the first occurrences. If this is not expected to happen often, a formula such as this could be used to alert the user to the existence of duplicates:
=IF(COUNTIF(B:B, MAX(B:B))>1, "Multiple Maximums ", INDEX(A:A, MATCH(MAX(B:B), B:B, 0)))
To make this formula work for minimums, just replace the two instances of MAX with MIN and change the word "Maximums" to "Minimums."
ExcelTips is your source for cost-effective Microsoft Excel training. This tip (9662) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Excel in Microsoft 365. You can find a version of this tip for the older menu interface of Excel here: Finding the Dates for Minimums and Maximums.
Best-Selling VBA Tutorial for Beginners Take your Excel knowledge to the next level. With a little background in VBA programming, you can go well beyond basic spreadsheets and functions. Use macros to reduce errors, save time, and integrate with other Microsoft applications. Fully updated for the latest version of Office 365. Check out Microsoft 365 Excel VBA Programming For Dummies today!
Because Excel stores dates internally as serial numbers, it makes doing math with those dates rather easy. Even so, it ...
Discover MoreNeed to figure out if a given year is a leap year? It's not as easy as you think! This tip provides a plethora of ways ...
Discover MoreExcel works very well with dates and times. One thing you cannot do, however, is to create a custom format that displays ...
Discover MoreFREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."
2021-04-03 13:06:09
Tom Kadlec
You can use VLOOKUP using the following formula:
=VLOOKUP(MIN(B:B), CHOOSE({1,2},B:B,A:A),2,FALSE)
=VLOOKUP(MAX(B:B), CHOOSE({1,2},B:B,A:A),2,FALSE)
Where CHOOSE({1,2},B:B,A:A) produces an array that effectively reverses the order of the columns A and B.
VLOOKUP searches for a match in the first column of the CHOOSE array (B:B - expenditure) and returns the value from the second column of the CHOOSE array (A:A - date).
This formula can be used to search non-adjacent columns or columns from different sheets.
Got a version of Excel that uses the ribbon interface (Excel 2007 or later)? This site is for you! If you use an earlier version of Excel, visit our ExcelTips site focusing on the menu interface.
FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."
Copyright © 2026 Sharon Parq Associates, Inc.
Please Note:
This article is written for users of the following Microsoft Excel versions: 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Excel in Microsoft 365. If you are using an earlier version (Excel 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Excel, click here:
Comments