Searching Very Large Strings in a Macro

In his macro, Ian needs to locate a short string within a very large string. The large string is essentially the text of an entire file, sometimes more than 180,000 characters. Neither Search() nor Find() works, unless he chops the large string into smaller parts (e.g., under 32,000 characters), and searches each part in turn. The problem with this dissection is that Ian doesn't know where within the file his target text may lie, or even whether it's in there, and it's quite possible that he might chop his target text and never be able to find it.

There are three general ways that you can search for the instance of one string within another in VBA:

• Find method
• Search method
• InStr function

The first two approaches are the ones that Ian specifically mentions, so he knows how to use these. They are actually methods, used with the WorksheetFunction object. They are essentially used to access the FIND and SEARCH worksheet functions from within VBA.

They aren't the best for finding information in a large, large string. For that you should use the InStr function, a function native to VBA. This is particularly true if your large, large string is being pulled in from a text file and does not actually reside within a workbook.

Let's say that you have a large text file you want to search for a particular text value. You can read the entire file into memory at one time in this manner:

Sub CheckFullFile()
    Dim sFullFile As String
    Dim sFindText As String
    Dim lFileSize As Long
    Dim lStart As Long
    Dim lLoc As Long
    Dim sMsg As String

    ' This is what you want to search for, in lowercase
    sFindText = "mytext"

    Open "c:\ReallyBigFile.txt" For Input As 1
    lFileSize = Lof(1)
    sFullFile = Input(lFileSize, 1)
    Close 1
    sFullFile = LCase(sFullFile)

    lStart = 0
    lLoc = InStr(sFullFile, sFindText)
    While lLoc > 0
        sMsg = sMsg & "Found at " & lLoc & vbCrLf
        lStart = lLoc + 1
        lLoc = InStr(lStart, sFullFile, sFindText)
    Wend
    MsgBox sMsg
End Sub

The macro opens the text file specified, stuffs the entire file contents into the sFullFile string, and displays all instances of the sFindText variable within that text. Note that the file contents are converted to lowercase. This is necessary because the InStr function is case sensitive. If you want your search to be case sensitive, you don't need to do the conversion.

The only effective limitation on code like this is the amount of memory you have in your system. VBA has an effective string length limitation of somewhere over 2 billion characters, but few systems have that much RAM in them. Of course, most text files you would be reading do not approach that file size, either. Testing with your actual data files will let you know if this read-n-the-full-file approach will work for you.

If you have a text file that has individual lines of text in it, as most do, then there is a more efficient way to process the file and look for your text. (Individual lines are those terminated with either a carriage return and/or line feed.)

Sub CheckEachLine()
    Dim sRaw As String
    Dim sFindText As String
    Dim lFileSize As Long
    Dim lStart As Long
    Dim lLoc As Long
    Dim sMsg As String

    ' This is what you want to search for, in lowercase
    sFindText = "mytext"

    Open "c:\ReallyBigFile.txt" For Input As 1

    Do Until Eof(1)
        Line Input #1, sRaw
        sRaw = LCase(sRaw)

        lStart = 0
        lLoc = InStr(sTemp, sFindText)
        While lLoc > 0
            sMsg = sMsg & "Found at " & lLoc & vbCrLf
            lStart = lLoc + 1
            lLoc = InStr(lStart, sRaw, sFindText)
        Wend
    Loop
    Close 1

    MsgBox sMsg
End Sub

With this approach, you don't have to really worry about the length of the text file since only a single line at a time is being read into memory and processed.

I'm sure you get the idea—InStr is the way to go when you want to work with finding information in amazingly large source strings.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13660) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Excel in Microsoft 365.