Modified Rounding

Samantha needs a formula that will round a value based on whether it is less than or equal to .25. So, for instance, 3.24 would round down to 3 and 3.25 (or greater) would round up to 4.

Rounding at the normal place (.5) is rather easy in Excel, as the program provides the ROUND worksheet function. When you want the "break point" for the rounding to be something other than .5, you'll need to rely on a formula and not on a simple worksheet function.

There are (literally) dozens of formulas you can devise to get the result you need. As with many things in Excel, the solution depends on the nature of your data. If the value to be rounded is always going to be positive, then the following formulas will work just fine. (I didn't include these formulas in any particular order other than sorting them alphabetically.)

=FLOOR(A1+0.75,1)
=IF(A1-INT(A1)<0.25,FLOOR(A1,1),CEILING(A1,1))
=IF(A1-INT(A1)<0.25,INT(A1),INT(A1)+1)
=IF(A1-INT(A1)<0.25,ROUNDDOWN(A1,0),ROUNDUP(A1,0))
=IF(INT(A1)=INT(A1+0.75),INT(A1),INT(A1)+1)
=IF(MOD(A1,1)<0.25,INT(A1),INT(A1)+1)
=IF(MOD(A1,1)<0.25,ROUNDDOWN(A1,0),ROUNDUP(A1,0))
=IF(MOD(A1,1)<0.25,TRUNC(A1,0),TRUNC(A1,0)+1)
=IF(MOD(A1,SIGN(A1))<0.25,ROUNDDOWN(A1,0),ROUNDUP(A1,0))
=IF(MOD(A1*100,100)>=25,ROUNDUP(A1,0),ROUNDDOWN(A1,0))
=INT(A1)+IF(A1-INT(A1)>=.25,1,0)
=INT(A1)+IF(MOD(A1,1)>=0.25,1,0)
=INT(A1+0.75)
=ROUND(A1,0) + IF(MOD(A1,1)>=.25,1,0)
=ROUND(A1+.25,0)
=ROUNDDOWN(A1-0.25,0)+1
=ROUNDDOWN(A1+0.75,0)
=ROUNDUP(A1-0.24,0)
=ROUNDUP(FLOOR(A1,0.25),0)
=TRUNC(A1)+(MOD(A1,1)>=0.25)

No doubt there could be even more formulas and variations of formulas to do the rounding. If the value to be rounded may include negative values, then you'll need to use a different formula. (Again, these are only sorted alphabetically.)

=IF(ABS(A1)-INT(ABS(A1))>=0.25,INT(A1)+IF(A1<0,0,1),INT(A1+IF(A1<0,1,0)))
=ROUND(A1+IF(A1>0,0.25,-0.25),0)
=ROUND(A1+SIGN(A1)*0.25,0)
=ROUND(ROUND(A1*2,0)/2,0)
=ROUNDUP(ROUNDDOWN((A1/0.25),0)*0.25,0)
=ROUNDUP(ROUNDDOWN(A1*4,0)/4,0)
=TRUNC(A1+SIGN(A1)*0.75)

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10126) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365.