Loading
ExcelRibbon.Tips.Net ExcelTips (Ribbon Interface)

Determining the RGB Value of a Color

Please Note: This article is written for users of the following Microsoft Excel versions: 2007, 2010, and 2013. If you are using an earlier version (Excel 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Excel, click here: Determining the RGB Value of a Color.

Neil uses colors a lot in his worksheets. He knows that he can generate a color based upon a numeric RGB value (and as explained in other ExcelTips issues). Neil would like to do the opposite—determine an RGB value. He wonders if there is a way to return (via function or macro) the RGB value of the color used to fill a cell. (Neil wants the actual color applied to the cell, not any "override" color, such as one imposed by a conditional format.)

Excel doesn't include a function to do this, but if you only need to check out the RGB values for a single cell, the easiest way is to follow these steps:

  1. Select the cell that is formatted with the color you want to check.
  2. Display the Home tab of the ribbon.
  3. Click the down-arrow at the right side of the Fill Color tool, in the Font group. Excel displays a small palette of colors and some other options.
  4. Choose More Colors. Excel displays the Colors dialog box.
  5. Make sure the Custom tab is displayed. (See Figure 1.)
  6. Figure 1. The Custom tab of the Colors dialog box.

  7. At the bottom of the dialog box you can see the individual values for the red, green, and blue components of the color in the cell.
  8. Click OK when done.

If you have a need to get the values more often, then creating your own user-defined function is the way to go. The function you use depends on what you want to actually have returned to your worksheet. For instance, if you want to have the traditional six-character hex code for RGB colors returned, you would use the following very simple macro:

Function getRGB1(rcell) As String
    Dim sColor As String

    sColor = Right("000000" & Hex(rcell.Interior.Color), 6)
    getRGB1 = Right(sColor, 2) & Mid(sColor, 3, 2) & Left(sColor, 2)
End Function

This macro looks at the interior color for any cell you reference, puts the hex values for the color in the right order, and returns the string to Excel. To use the function you simply invoke it, in your worksheet, with a cell referenced in this manner:

=getRGB1(B4)

You may not want the traditional hex codes for the RGB colors, however. If you want to get the decimal values for each of the colors, then the following macro returns that:

Function getRGB2(rcell) As String
    Dim C As Long
    Dim R As Long
    Dim G As Long
    Dim B As Long

    C = rcell.Interior.Color
    R = C Mod 256
    G = C \ 256 Mod 256
    B = C \ 65536 Mod 256
    getRGB2 = "R=" & R & ", G=" & G & ", B=" & B
End Function

Invoked the same way as the getRGB1 macro, this version returns a string such as "R=255, G=204, B=0". You can also modify the macro even further so that it returns a single value, based upon a parameter you set:

Function getRGB3(rcell As Range, Optional opt As Integer) As Long
    Dim C As Long
    Dim R As Long
    Dim G As Long
    Dim B As Long

    C = rcell.Interior.Color
    R = C Mod 256
    G = C \ 256 Mod 256
    B = C \ 65536 Mod 256

    If opt = 1 Then
        getRGB3 = R
    ElseIf opt = 2 Then
        getRGB3 = G
    ElseIf opt = 3 Then
        getRGB3 = B
    Else
        getRGB3 = C
    End If
End Function

To use the macro, simply add a second parameter to the function used in your worksheet, specifying what you want:

=getRGB3(B4,1)

If the second parameter is 1, then the function returns just the red value. If you specify a second parameter of 2, then the green value is returned, and 3 returns the blue value. Any other value for the second parameter (or if you omit it entirely) returns the full decimal value of the interior color.

If you don't want to go the route of creating a macro, or if you want to determine colors in more than just your Excel worksheet, you might consider a third-party utility. One that looks interesting is Instant Eyedropper, which is free. You can find more information about it here:

http://instant-eyedropper.com

This utility works with versions of Windows up through 2007; you may be able to search the Internet and find similar utilities that will work with Windows 8.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10180) applies to Microsoft Excel 2007, 2010, and 2013. You can find a version of this tip for the older menu interface of Excel here: Determining the RGB Value of a Color.

Related Tips:

Professional Development Guidance! Four world-class developers offer start-to-finish guidance for building powerful, robust, and secure applications with Excel. The authors show how to consistently make the right design decisions and make the most of Excel's powerful features. Check out Professional Excel Development today!

 

Comments for this tip:

Bigger Don    13 Nov 2014, 10:42
@ Willy

You are absolutely right, but hard-coding each assignment, cell-by-cell, would be more code and more maintenance over the development and operational life of the project, right?

I use a lot of what I call "formatting by exemplar" (using the font/colors/borders etc from one cell and applying it to others) so I converted my standard Sub by making the parameters into variables, adding the Set assignments, and removing all of the other formatting that can be passed from one cell to another.

By using the exemplar formatting approach I can have users, using Excel, show me exactly what they want to see as far as format is concerned. I can give them an first cut layout. from that point many of them can work through the process. With others, where I have to drive the mouse, it eliminates a lot of note-taking in meetings as well as "Could you make it light/darker greener/bluer then get back with me?" discussions.

On the back end, give those cells meaningful Names, e.g. on one project I have "fmtReleaseBanner" and "fmtNotesHeader" then I can pass the named range and the target range to one subroutine that performs the same action, whether it is in the NewMonth, UpdateForMeeting, or PublishResults main Sub.

Just my opinion!
Willy Vanhaelen    12 Nov 2014, 10:45
Here is a much shorter version of the getRGB3 function in this tip:

Function getRGB3(rcell As Range, Optional opt As Integer) As Long
   Dim C As Long
   C = rcell.Interior.Color
   Select Case opt
      Case 1: getRGB3 = C Mod 256
      Case 2: getRGB3 = C \ 256 Mod 256
      Case 3: getRGB3 = C \ 65536 Mod 256
      Case Else: getRGB3 = C
   End Select
End Function
Willy Vanhaelen    12 Nov 2014, 10:44
@ Bigger Don

If you put the macro in the sheet's code page you can reduce it to one line:

Sub copycolor()
   Range("A3").Interior.Color = Range("D3").Interior.Color
End Sub
Bigger Don    11 Nov 2014, 12:47
@ James

Why worry about the Hex value unless you want to manipulate it before assigning it to another cell? You can simply assign one cell's Interior.Color directly to another.

Sub copycolor()
    Dim rng1 As Range
    Dim rng2 As Range
    Set rng1 = Worksheets("Sheet1").Range("D3")
    Set rng2 = Worksheets("Sheet1").Range("A3")
    rng2.Interior.Color = rng1.Interior.Color
    
End Sub
James Wilson    10 Nov 2014, 22:01
I don't want to get the RGB, I want to set the RGB. Read the sColor hex from a cell and set that as the background colour of the cell "Asking".

Cheers Jim

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 4+5 (To prevent automated submissions and spam.)
 
          Commenting Terms
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2013)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2013)

Our Products

Premium Newsletters

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2014 Sharon Parq Associates, Inc.