Deleting Every X Rows

Re. my previous comment below, My Excel Toolbox now includes the following two macros:
    DeleteEveryNthRow -- Delete every Nth row of the selected range
    DeleteEveryNthCol -- Delete every Nth column of the selected range
See https://sites.google.com/view/MyExcelToolbox/

Here's my version of the Tip's macro:

Sub DeleteRows2()
    Const myName = "DeleteRows2"
    Dim nStart As Long, nCount As Long, nEnd As Long, nStep As Long
    Dim nSelecRows As Long, rSelecCells As Range, rDelete As Range
    Dim n As Long, msg As String
    Set rSelecCells = Selection
    For n = 1 To rSelecCells.Areas.Count 'might be non-contiguous
        nSelecRows = nSelecRows + rSelecCells.Areas(n).Rows.Count
    Next n
    Selection.Areas(1).EntireRow.Select 'selection of contiguous rows
    nStart = Selection.Cells(1).Row
    nCount = Selection.Rows.Count
    nEnd = nStart + nCount - 1
    msg = "To delete every Nth row of the selected range " & vbLf _
        & "$" & nStart & ":$" & nEnd & " starting with row $" _
        & nStart & ", enter a value for " & vbLf & "increment N:"
    nStep = Int(Application.InputBox(msg, myName, 0, Type:=1))
    If nStep < 1 Then
        rSelecCells.Select
        MsgBox "No rows were deleted.", , myName
        Exit Sub
    End If
    nEnd = nStart + nStep * ((nCount - 1) \ nStep) 'integer division
    Set rDelete = Rows(nStart).EntireRow
    For n = (nStart + nStep) To nEnd Step nStep
        Set rDelete = Application.Union(rDelete, Rows(n).EntireRow)
    Next n
    rDelete.Select
    msg = "The selected rows will be deleted."
    If MsgBox(msg, vbOKCancel, myName) = vbOK Then
        nSelecRows = nSelecRows - rDelete.Rows.Count
        rDelete.Delete
    End If
    If nSelecRows > 0 Then rSelecCells.Select Else ActiveCell.Select
End Sub

If VB is too much for you:
add the following in a new column:

=MOD(ROW()-X,Y)

1. where X is the first data row (after headers) and Y is the number of rows to count.
2. first row for the formula=first DATA row.
3. drug all the way down.
4. filter OUT the zeros.
5. delete all the rows and remove filter.