Adding and Formatting a Shape via Macro

Ron often uses Shapes (an oval, actually) to highlight things in a worksheet. He adds and sizes the shape, then he needs to change the shape color to red and delete any fill color so that it doesn't obscure what he's actually trying to highlight. He performs these steps quite often, and has no doubt this could somehow be sped up with a macro, but he's not sure how to go about it.

Before looking at macro-based solutions, you might want to consider some that don't require macros. For instance, if you create your oval (formatted as desired) and then right-click on it, you can set it as your default shape. This can speed the addition of the shape to your workbook in the future.

If you have multiple shapes, each a different size and color, you may want to simply copy those shapes to a different workbook. That workbook could be a "holder" for those shapes, so that you can copy them back to other workbooks, as needed. This is a great way to build your own gallery of standard shapes that can be used for years.

If you decide that a macro is the best way to go, then it is relatively easy to use one to add the oval. Here's a very simple one:

Sub Custom_Oval1()
    ActiveSheet.Shapes.AddShape(msoShapeOval, 150, 150, _
      120, 60).Select
    Selection.ShapeRange.Fill.Visible = msoFalse
    With Selection.ShapeRange.Line
        .DashStyle = msoLineSolid
        .Weight = 3
        .Visible = msoTrue
        .ForeColor.RGB = RGB(255, 0, 0)
        .Transparency = 0
    End With
End Sub

This inserts a standard oval, with desired color, fill, and transparency, at a single location in the worksheet. When it is done, the shape is still selected and you can then drag the oval to where you desire and make any adjustments in size that may be necessary.

If you prefer to have the oval closer to where you want, you can use a variation that looks at the active cell in the worksheet and places the oval around that cell, sized to the height and width of the cell:

Sub Custom_Oval2()
    Dim lLeft As Long
    Dim lTop As Long
    Dim lWidth As Long
    Dim lHeight As Long

    lLeft = ActiveCell.Left - 5
    lWidth = ActiveCell.Width + 5
    lTop = ActiveCell.Top
    lHeight = ActiveCell.Height + 5

    ActiveSheet.Shapes.AddShape(msoShapeOval, lLeft, _
      lTop, lWidth, lHeight).Select
    Selection.ShapeRange.Fill.Visible = msoFalse
    With Selection.ShapeRange.Line
        .DashStyle = msoLineSolid
        .Weight = 3
        .Visible = msoTrue
        .ForeColor.RGB = RGB(255, 0, 0)
        .Transparency = 0
    End With
End Sub

Note that this variation of the macro determines the location for the shape based on the location of the ActiveCell object. You could, if desired, change all occurrences of ActiveCell to Selection, which would allow the size of the oval to adjust to surround your selection rather than simply the active cell. Note, as well, that the left, width, and height values are adjusted slightly to give the oval a better fit. You may want to play with different adjustment values to get just the look you want.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (4631) applies to Microsoft Excel 2007, 2010, 2013, and 2016.