Specifying Chart Sizes in Inches

When Tonya creates charts, most all of them are embedded in a worksheet. Excel sizes the charts based on the data in the chart, which means they are often different sizes. Tonya needs to click and drag the sizing handles to adjust the chart sizes, which is tedious. She wonders if there is a way she can specify a size for the embedded charts in inches. This would make her work much easier.

If you just have a couple of charts to size, the easiest way is to follow these steps:

1. Click once on the chart to select it. Excel displays adds two new tabs to the ribbon.
2. Display the Format tab of the ribbon. (This is one of the two new tabs added to the ribbon after step 1.)
3. At the right end of the ribbon, specify a Height and Width in inches.

Easy, right? There's another easy way—click once on the chart and then press Ctrl+1. Excel displays, at the right side of the screen, the Format Chart Area task pane. Click the Size & Position icon, and then make sure the Lock Aspect Ratio check box is cleared. You can then specify the desired chart size in inches.

If you have many more charts to resize, or if you have to perform the task quite often, then a macro-based solution may be best for your needs. Here's a version that will work on whatever chart is currently selected:

Sub ResizeSelectedChart()
    Dim Height As Single
    Dim Width As Single

    ' Set width and height to standard values
    Width = 6.25
    Height = 4.1

    If TypeName(Selection) = "ChartArea" Then
        With ActiveChart.Parent
            .ShapeLockAspectRatio = msoFalse
            .Width = Width * 72
            .Height = Height * 72
        End With
    Else
        MsgBox "Chart not selected", vbExclamation
    End If
End Sub

Note that you cannot select an object within the chart; you must select the entire chart before running the macro. It sets the width and height according to the values you store in the Width and Height variables. Specifically, the Width and Height variables are multiplied by 72 because the Width and Height properties expect values to be specified in points. Notice, as well, that the macro sets the ShapeLockAspectRatio property to msoFalse. This is done just in case the aspect ratio has been locked for the chart.

If you prefer to have the macro affect all embedded charts in the entire workbook, then the following will work fine:

Sub ResizeAllEmbeddedCharts()
    Dim ws As Worksheet
    Dim ch As ChartObject
    Dim Height As Single
    Dim Width As Single

    ' Set desired size in inches
    Width = 6.25
    Height = 4.1

    ' Loop through each worksheet in the workbook
    For Each ws In ThisWorkbook.Worksheets
        For Each ch In ws.ChartObjects
            With ch
                .ShapeLockAspectRatio = msoFalse
                .Width = Width * 72
                .Height = Height * 72
            End With
        Next ch
    Next ws

    MsgBox "All embedded charts have been resized.", vbInformation
End Sub

If your workbook contains any chart sheets (charts that are not embedded), they will not be affected by the macro.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13950) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Excel in Microsoft 365.