Seeing If a Workbook Has Been Saved

@J. Woolley:
Yes, Dave asked if there is a way to display the save status in a CELL, but he also mentioned that in Word you can easily see the save status. I am not sure why he observes the difference, may be he uses an older version of Excel or Office.

Asking for the Save Status to be placed in a cell is creating a Catch 22 situation, whatever you place in the selected cell will make the workbook not saved. That is why an User Defined Function shown below will **always** return FALSE if used in a cell:

Public Function isSaved()
    Application.Volatile
    isSaved = ActiveWorkbook.Saved
End Function

It will return FALSE even if you have AutoSave into OneDrive, which is supposed to save all changes on the fly.

You can override the save status, like Allen has proposed, by explicitly changing it back to what it was before the check and placing the status in a cell, but that would make a file that was modified and actually not saved thereafter, reported as saved. Such approach will get what David asked for, but ...

I cannot see the utility of having such information in a cell. Would you depend on such cell in your spreadsheet calculations? If so you would depend on potentially incorrect status, as it may or may not be updated.

My suggestion of the message box with the save status is more dependable, as it does not change the workbook. If you need for a macro to depend on the save status, you can check it within the macro without changing the workbook as well.

The message box will also indicate whether the workbook was actually saved if you use OneDrive. As I mentioned in my comment, there is a delay between modification of the workbook and the OneDrive AutoSave catching up. That delay in my experience can be as long as 2 minutes. In this scenario, although the Title Bar will indicate "Saved" almost immediately after the changes, if you have a power outage or computer crash during this delay, those last changes will probably be lost.

@Tomek
Yes, there are several problems. But remember Dave "wonders if there is some way to have the program display info in a CELL that would indicate whether or not the workbook has been saved."

In my opinion all these macro based approaches are like using big guns to kill a mosquito. Additionally, there are several problems, some of them mentioned by Alex Blakenburg and J. Woolley.
The indicator in the Title Bar "Saved" or "Saved to this PC" should be sufficient and not clutter your actual workbook. For earlier versions of Excel that do not show this indicator I suggest a simple macro that should be placed in your PERSONAL.XLSB:

Public Sub infoSaved()
    MsgBox ActiveWorkbook.Saved, , "Is the Workbook Saved?"
End Sub

Assign this macro to you Quick Access Toolbar and click on the icon whenever you need this information.

There is one glitch if you use OneDrive and set the AutoSave option: the Title Bar indicator will show your workbook as "Saved" after you make some change to the workbook (it is AutoSave after all), while the macro above will still tell you "FALSE" at least for a while. But the workbook will get saves when you exit it.

NOTE also the difference in the Title Bar indicator from "Saved to this PC" to just "Saved" if you use One Drive.

There are several reasons why the Tip's VBA procedures will not work as described:
1. As noted by Alex Blakenburg, if Sub UpdateSaveStatus is located in a standard module, then it must not be declared Private; otherwise, it will not be available to procedures in the ThisWorkbook module. It might be better to retain UpdateSaveStatus as a Private Sub and locate it in the ThisWorkbook module so it can only be referenced locally.
2. Cell A1 on every worksheet must be reserved for use by UpdateSaveStatus.
3. UpdateSaveStatus updates the value of cell A1 on any worksheet that is currently active but not when that worksheet is inactive; therefore, cell A1 will not reliably indicate the current status when that worksheet is reactivated.
4. When a sheet is calculated the workbook usually becomes unsaved, but cell A1 is not appropriately updated.
5. Workbook_AfterSave calls 'UpdateSaveStatus True' even if Success is False and the workbook is not saved. ActiveWorkbook.Saved is automatically updated by Excel; it is not normally set in VBA unless you want to close an unsaved workbook without a Save prompt.
Here's an alternate method that resolves these issues. First pick a single cell to display the save status and use Formulas > Define Name (Alt+M,M,D) to name that cell SaveStatus with Workbook scope. Then add the following VBA to the ThisWorkbook module:

Private Sub Workbook_AfterSave(ByVal Success As Boolean)
    If Not Success Then UpdateSaveStatus False
End Sub

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, _
    Cancel As Boolean)
    UpdateSaveStatus True
End Sub

Private Sub Workbook_SheetCalculate(ByVal Sh As Object)
    UpdateSaveStatus False
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, _
    ByVal Target As Range)
    UpdateSaveStatus False
End Sub

Private Sub UpdateSaveStatus(arg As Boolean)
    Application.EnableEvents = False
    Range("SaveStatus") = IIf(arg, "", "Not ") & "Saved"
    Application.EnableEvents = True
End Sub

Notice any sheet can display the current save status by entering the following formula in a cell: =SaveStatus
This method might not cover all event scenarios. Please describe any issues you observe.
Finally, this method is impractical for reasons described by Alex Blakenburg.

If you are going to place the "UpdateSaveStatus" sub in a standard module as indicated, you need to drop the "Private" keyword before "Private Sub UpdateSaveStatus" or you will get "Compile Error : Sub or Function not defined".
Also a more significant draw back than making the workbook an XLSM file is that since you are running an update macro each time you make a change to a sheet, it will clear the Undo Stack for that workbook. So Undo / Ctrl+Z will no longer work.