Clearing Everything Except Formulas

Roni wants to clear everything in a worksheet except for cells which may contain formulas. This task can be completed either manually or through the use of a macro.

If you want to do the clearing manually, you can follow these steps:

1. Press F5. Excel displays the Go To dialog box. (See Figure 1.)



Figure 1. The Go To dialog box.

2. Click the Special button. Excel displays the Go To Special dialog box. (See Figure 2.)



Figure 2. The Go To Special dialog box.

3. Select the Constants radio button. The four check boxes under the Formulas option then become available. (This can be a bit confusing. Why Microsoft made the Constants radio button control some check boxes under a different radio button is not immediately clear.)
4. Make sure that all the check boxes under the Formulas radio button are selected. (They should be selected by default.)
5. Click OK. Excel selects all the constants (cells that don't contain formulas) in the worksheet.
6. Press the Del key.

This works great if you only need to clear out the non-formula contents of a worksheet once in a while. If you need to do it more often, then you can simply use the macro recorder to record the above steps. Or, if you prefer, you can create your own macro from scratch, such as the following one:

Sub ClearAllButFormulas()
    Dim wks As Worksheet

    'Ignore errors in case there are only formulas
    On Error Resume Next
    For Each wks In Worksheets
        wks.Cells.SpecialCells(xlCellTypeConstants).ClearContents
    Next
    On Error GoTo 0
    Set wks = Nothing
End Sub

This macro is particularly useful if you need to clear out all the non-formula cells in an entire workbook. The reason is because it does the clearing on every worksheet in the entire workbook, without you needing to do the clearing manually.

You should use caution when using this macro. Make sure you really do want to clear out everything except for cells that contain formulas in the worksheet or workbook before you run this macro. It would be a shame to accidentally get rid of the contents of cells that you really needed to keep. If you are a bit squeamish about such a possibility, you might want to use the following version of the macro:

Sub ClearAllButFormulas2()
    Dim wks As Worksheet
    Dim sTemp As String
    Dim iCheck As Integer

    sTemp = "This macro deletes everything in the current "
    sTemp = sTemp & "workbook except formulas. Once done, "
    sTemp = sTemp & "it cannot be undone." & vbCrLf & vbCrLf
    sTemp = sTemp & "Are you sure you want to continue?"

    iCheck = MsgBox(sTemp, vbYesNo + vbExclamation, "Warning!")

    If iCheck = vbYes Then
        'Ignore errors in case there are only formulas
        On Error Resume Next
        For Each wks In Worksheets
            wks.Cells.SpecialCells(xlCellTypeConstants).ClearContents
        Next
        On Error GoTo 0
    Else
        MsgBox "Operation cancelled."
    End If
End Sub

This version displays a message box asking if you are sure you want to do the clearing. The upshot is that you have less of a chance of messing up your workbook by accident.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (9097) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, Excel in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Excel here: Clearing Everything Except Formulas.