Jumping to the Real Last Cell

Re. my most recent comment below, these changes will make the ClearEmpties3 macro run faster.
Replace this statement
    If Len(Trim(ConvUniSpaces(WorksheetFunction.Clean(c.Value)))) = 0 Then
with this statement
    If Len(RemoveUniSpaces(WorksheetFunction.Clean(c.Value))) = 0 Then
and replace the ConvUniSpaces function with the following function:

Function RemoveUniSpaces(Text As String) As String
    Const UniSpaces = "\s|[\u00A0\u2000-\u200A\u202F\u205F\u3000]"
    With CreateObject("VBScript.RegExp")
        .Pattern = UniSpaces: .Global = True
        RemoveUniSpaces = .Replace(Text, vbNullString)
    End With
End Function

It might be necessary to use VB Editor's Tools menu to Reference the Microsoft VBScript Regular Expressions 5.5 library. The latest version of the VBA library includes RegExp; in this case, you can replace this late binding statement
    With CreateObject("VBScript.RegExp")
with this statement
    With New RegExp
for early binding, but the macro will probably fail when using Excel 2024 or an earlier version.

@Alex Blakenburg
Thank you for your comment. I was not aware the SpecialCells problem was fixed in Excel 2010. Here's another version of the macro that addresses merged cells and Unicode space characters plus status bar display.

Sub ClearEmpties3()
        Dim c As Range, J As Long, K As Long, sSB As String, bDSB As Boolean
        ActiveSheet.UsedRange.Select
        On Error Resume Next
                Selection.SpecialCells(xlCellTypeConstants, xlTextValues).Select
                If Err Then Exit Sub
        On Error GoTo 0
        sSB = Application.StatusBar
        bDSB = Application.DisplayStatusBar
        Application.DisplayStatusBar = True
        K = Selection.Cells.Count
        For Each c In Selection
                J = J + 1: Application.StatusBar = J & " of " & K
                If Len(Trim(ConvUniSpaces(WorksheetFunction.Clean(c.Value)))) = 0 Then
                        c.MergeArea.Clear
                End If
        Next c
        Application.StatusBar = IIf(sSB = "FALSE", False, sSB)
        Application.DisplayStatusBar = bDSB
        ActiveSheet.UsedRange.Select
End Sub

Function ConvUniSpaces(Text As String) As String
        Static UniSpaces As Variant, n As Integer
        If IsEmpty(UniSpaces) Then
                UniSpaces = Array(ChrW(&HA0), "NO-BREAK SPACE", _
                        ChrW(&H2000), "EN QUAD", _
                        ChrW(&H2001), "EM QUAD", _
                        ChrW(&H2002), "EN SPACE", _
                        ChrW(&H2003), "EM SPACE", _
                        ChrW(&H2004), "THREE-PER-EM SPACE", _
                        ChrW(&H2005), "FOUR-PER-EM SPACE", _
                        ChrW(&H2006), "SIX-PER-EM SPACE", _
                        ChrW(&H2007), "FIGURE SPACE", _
                        ChrW(&H2008), "PUNCTUATION SPACE", _
                        ChrW(&H2009), "THIN SPACE", _
                        ChrW(&H200A), "HAIR SPACE", _
                        ChrW(&H202F), "NARROW NO-BREAK SPACE", _
                        ChrW(&H205F), "MEDIUM MATHEMATICAL SPACE", _
                        ChrW(&H3000), "IDEOGRAPHIC SPACE")
        End If
        ConvUniSpaces = Text
        If Len(ConvUniSpaces) > 0 Then 'replace UniSpaces with ASCII space
                Const A_SPACE = " "
                For n = LBound(UniSpaces) To UBound(UniSpaces) Step 2
                        ConvUniSpaces = Replace(ConvUniSpaces, UniSpaces(n), A_SPACE)
                Next n
        End If
End Function

We don't really have enough information to provide a robust code solution. With the data being "imported" formatting is unlikely to be an issue. Neither macro handles non-breaking spaces (ASCII 160) but that also seems unlikely for an imported file. Both macros will fail if there are merged cells, again unlikely for an imported file.

A non-US regional setting could impact dates in the original macro provided but unlikely to impact numbers (they will stay as numbers despite the use of Trim).
Looping through almost 50k rows 1 cell at a time is not going to be quick. if there a lot of empty cells sprinkled through the 50k rows, you will wind up with a large number of non-contiguous cells in the selection.
@J. Woolley - Re: 8,192 non-contiguous ranges (Areas) limit.
Refer to:
https://jkp-ads.com/rdb/win/s4/win003.htm
"Note: This problem is fixed in Excel 2010
Non-contiguous cells that can be selected in Excel 2010 : 2,147,483,648 cells"

Mind you I tested it on around 30k areas and the macro gets really ... slow as the number of non-contiguous ranges increases.

The Tip's ClearEmpties macro starts with the following statement:
        Selection.SpecialCells(xlCellTypeConstants, 23).Select
The result will be unreliable unless the user selects all cells (Ctrl+A) before running the macro. And the macro has some undesirable side effects for cells that contain a text constant:
1. If the text is numeric it is converted to a number (non-text).
2. If the text is a date it is probably converted to a number (non-text).
3. If the text has leading or trailing space characters they are removed.
These side effects become permanent if the workbook is saved. Finally, cells that contain only non-printing characters and/or line breaks (with or without space characters) should be cleared but are not.
Here's an alternate version that resolves these issues:

Sub ClearEmpties2()
        Dim c As Range
        ActiveSheet.UsedRange.Select
        For Each c In Selection.SpecialCells(xlCellTypeConstants, xlTextValues)
                If Len(Trim(WorksheetFunction.Clean(c.Value))) = 0 Then c.Clear
        Next c
        ActiveSheet.UsedRange.Select
End Sub

ClearEmpties2 ignores the StatusBar because it runs too quickly for the user to notice. ActiveSheet.UsedRange updates the last used cell, so it is not necessary to save the workbook in order to reset Ctrl+End.
Warning: The SpecialCells method fails silently if it identifies more than 8,192 non-contiguous ranges (Areas), but this is unlikely.

A couple of points about the "simple" answer :-

There is no need to get out of Excel and reopen the workbook.
After saving, you can keep the workbook open and immediately test the location of the last cell with Ctrl-End.

This resetting of the last cell automatically works for EVERY worksheet in the workbook, not just the active worksheet.
There is no need to repeat the process for the other worksheets.

FYI - It is the Save function of the workbook that recalculates the UsedRange on which the Ctrl+End relies. So after the macro Ctrl+End should change after you hit Save. There should be no need to Close and ReOpen the workbook.

PS: Also both references to the StatusBar should say Application.StatusBar (with Option Explicit set - the current code errors out)