Counting the Times a Worksheet is Used

You may want a way to keep track of how many times a particular worksheet is used. There are many ways you can accomplish this. One simple way is to just store the count in the worksheet itself. Right-click a worksheet tab, then choose View Code from the Context menu. Excel displays the Visual Basic Editor, where you should paste the following code:

Private Sub Worksheet_Activate()
    Range("A1").Select 'customize Range
    ActiveCell = ActiveCell + 1
    Range("B1") = "times opened" 'customize Range
End Sub

This code increments the value in cell A1 every time the worksheet is activated. You can modify the cell locations where the macro writes its information, according to your needs.

A more thorough approach is to create a macro that increments named references within the workbook. Consider the following macro:

Function IncrementEventCounter(sName As String, sht As Object)
    On Error Resume Next
    If sht.Names(sName) Is Nothing Then _
      ThisWorkbook.Names.Add "'" & sht.Name & "'!" & sName, "1", False
    On Error GoTo 0
    With ThisWorkbook.Names("'" & sht.Name & "'!" & sName)
        .RefersTo = Val(Mid(.Value, 2)) + 1
    End With
End Function

This function is designed to be called from a different macro—one triggered by the event that should cause the usage counter to increment. For instance, if you want to keep track of every time the worksheet is activated, then you would use the following macro as part of the ThisWorkbook object:

Private Sub Workbook_SheetActivate(ByVal sh As Object)
    IncrementEventCounter "Activated", sh
End Sub

The macro increments a counter named "Activated" for the worksheet. It does this by calling the IncrementEventCounter macro, with the name of the counter and the name of the worksheet. If, instead, you wanted to count the number of times that a worksheet was changed, you could use the following macro as part of the ThisWorkbook object:

Private Sub Workbook_SheetChange(ByVal sh As Object, _
  ByVal Target As Excel.Range)
    IncrementEventCounter "Changed", sh
End Sub

The only difference between this macro and the previous one is that it increments a counter named "Changed." To see the values of the counters, just enter a formula in a cell that references the counter. For instance, you could enter =Changed to see the value of the Changed counter, or =Activated to see the value of the Activated counter. The value of each counter will differ from sheet to sheet, since the counters are maintained on a sheet-by-sheet basis.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10544) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and 2021. You can find a version of this tip for the older menu interface of Excel here: Counting the Times a Worksheet is Used.