Sheets for Months

When you are starting a new workbook, it is very common to name each worksheet after a different month of the year. If you do this quite a bit, you know it can be tiresome to rename each worksheet, in turn, to exactly what you need.

The following macro was developed to help in these situations. It checks the names of the worksheets in your workbook, renaming them to the months of the year if they begin with the letters "Sheet". If there are not enough sheets in the workbook, it adds sheets, as necessary, for each month of the year.

Sub DoMonths()
    Dim J As Integer
    Dim K As Integer

    For J = 1 To 12
        If J <= Sheets.Count Then
            If Left(Sheets(J).Name, 5) = "Sheet" Then
                Sheets(J).Name = MonthName(J)
            Else
                Sheets.Add.Move after:=Sheets(Sheets.Count)
                ActiveSheet.Name = MonthName(J)
            End If
        Else
            Sheets.Add.Move after:=Sheets(Sheets.Count)
            ActiveSheet.Name = MonthName(J)
        End If
    Next J

    For J = 1 To 12
        If Sheets(J).Name <> MonthName(J) Then
            For K = J + 1 To Sheets.Count
                If Sheets(K).Name = MonthName(J) Then
                    Sheets(K).Move Before:=Sheets(J)
                End If
            Next K
        End If
    Next J

    Sheets(1).Activate
End Sub

The last step in the macro is that it places the worksheets in proper order, for the months 1 through 12. The result is that if you have any other worksheets left in the workbook (in other words, you had some that did not begin with the letters "Sheet", then those worksheets end up at the end of the workbook, after the 12 months.

Note that the macro utilizes the MonthName function, which is built into VBA. It returns the full name of the month referenced by number (1 through 12) passed to it. (If you try to use it with a number outside that range, it returns an error.)

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (11148) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and 2021. You can find a version of this tip for the older menu interface of Excel here: Sheets for Months.