Printing Selected Worksheets

If you have a lot of workbooks that have accumulated over the years, you may have a need to print some of the worksheets out of each of them. For instance, you might have a folder that contains a workbook for each of your company's divisions for the previous decade. If your company has eight divisions, that means you have 80 workbooks in the folder. Now, if you need to print the second-quarter and third-quarter figures (from the second and third worksheets out of each workbook), you start to see the problem. Loading each workbook and then printing selected sheets could take a huge amount of time.

A quicker way is to create a macro that will do the printing for you. The following macro starts by asking you for a directory path. Provided that you specify a path, the macro then starts to load each workbook file in the directory, and then prints the second and third worksheet from each one. (The macro doesn't really care what type of workbook files are in the directory—they could be XLS, XLSX, or XLSM files. It should load them all.) Once printed, the workbook is closed.

Public Sub PrintWorkbooks()
    Dim sCurFile As String
    Dim sPath As String

    'Get the path
    sPath = InputBox("Starting path?", "PrintWorkbooks")
    If sPath <> "" Then
        On Error Resume Next
        Application.ScreenUpdating = False
        If Right(sPath, 1) <> "\" Then
            sPath = sPath & "\"
        End If
        sCurFile = Dir(sPath & "*.xls*", vbNormal)
        Do While Len(sCurFile) <> 0
            Workbooks.Open sPath & sCurFile, , True
            With Workbooks(sCurFile)
                .Worksheets(2).PrintOut
                .Worksheets(3).PrintOut
                .Close SaveChanges:=False
            End With
            sCurFile = Dir
            DoEvents
        Loop
        Application.ScreenUpdating = True
        On Error GoTo 0
    End If
End Sub

Obviously, if you have quite a few workbooks in the directory, printing could take quite some time. You may want to find some time when you have nothing else to do, and then just let the macro start running.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (11316) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, Excel in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Excel here: Printing Selected Worksheets.