Printing Based on Cell Contents

Theresa wonders if there is a way to format a cell so that if the contents of the cell meet certain criteria then a specific worksheet is automatically printed. The short answer is no, there is no way to use formatting to achieve this goal. You can, however, use an event handler macro to do the printing.

For example, one of the event handlers supported by Excel is triggered every time something in the workbook is changed. You can create an event handler that examines which cell was changed. If it is a specific cell, and if that cell contains a particular value, then a worksheet can be printed.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$B$2" Then
        If Target.Value = 1001 Then
            Worksheets(1).PrintOut
        End If
    End If
End Sub

This macro examines which cell was changed. If it was cell B2 and if the cell contains the value 1001, then the worksheet is automatically printed.

Of course, you may want the contents of a particular cell to control what is printed when someone actually chooses to print. For instance, if the user chooses to print, you may want to examine the contents of a cell (such as E2) and, based on the contents of that cell, automatically modify what is printed. The following macro takes this approach:

Private Sub Workbook_BeforePrint(Cancel As Boolean)
    Application.EnableEvents = False
    Select Case Worksheets("Sheet1").Range("E1")
        Case 1
            Worksheets("Sheet1").PrintOut
        Case 2
            Worksheets("Sheet2").PrintOut
        Case 3
            Worksheets("Sheet3").PrintOut
        Case 4
            Worksheets("Sheet4").PrintOut
        Case Else
            ActiveSheet.PrintOut
    End Select
    Cancel = True
    Application.EnableEvents = True
End Sub

The macro prints Sheet1, Sheet2, Sheet3, or Sheet4 depending on whether cell E2 contains 1, 2, 3, or 4.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (11578) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, Excel in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Excel here: Printing Based on Cell Contents.