Forcing Dates Forward

Roger is keeping track of invoices in an Excel worksheet. All of the invoices need to be submitted with a due date for the 28th of the month, and Roger wondered if there was a way to force a date to always "jump forward" to the next instance of the 28th.

The cleanest way to force dates forward is to create a formula that will examine a date in a cell and then force that date to the next desired date, such as the 28th. The following formula is a good one to start with:

=IF(DAY(A1)>28,DATE(YEAR(A1),MONTH(A1)+1,28),
DATE(YEAR(A1),MONTH(A1),28))

Remember that this is a single formula; it is entered into a single cell. This formula examines the date in cell A1. If the DAY value of the date is greater than 28, then the formula constructs and returns a date that is equal to the 28th of the next following. If it is less than or equal to 28, then the 28th of the current month is returned.

There is an even shorter way to render an acceptable formula, however—one that entirely gets rid of the IF function:

=DATE(YEAR(A1),MONTH(A1)+(DAY(A1)>28),28)

This uses the current year as the year, and the day is always 28. The month uses a Boolean calculation. If the day is greater than 28, then (Day(A1)>28) will be TRUE and will calculate as a 1, thereby adding 1 to the current month. If it is less than or equal to 28 it will be FALSE and calculate as a 0, just calculating the current month.

If you don't want to be "strict" giving some people only a day (4/27/2012 will give a due date of 4/28/2012), you could plan on giving them at least a week with the formula:

=DATE(YEAR(A1),MONTH(A1)+(DAY(A1)>21),28)

This would give the 28th of the current month for the 1st thru 21st, but for later dates it will jump to the 28th of the following month.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (11603) applies to Microsoft Excel 2007, 2010, 2013, and 2016. You can find a version of this tip for the older menu interface of Excel here: Forcing Dates Forward.