Creating a Center Across Selection Button

As with most user macros, the Tip's CenterAcrossColumns macro does not support Undo. After running the macro, pressing Ctrl+Z will not restore the selection's previous horizontal alignment. On the other hand, My Excel Toolbox includes a CenterAcrossSelection macro with support for both Undo (Ctrl+Z) and Redo/Repeat (Ctrl+Y). It can also be assigned to the Quick Access Toolbar (QAT). Here is an abbreviated version:

Public Sub CenterAcrossSelection()
    CenterAcross_Do Action:=0 ' Do
End Sub

Private Sub CenterAcross_Do(Action As Integer)
    Static WB As Workbook, WS As Worksheet, R As Range, HA As Variant
    Dim sProc As String
    Const sName As String = "CenterAcross"
    If Action = 0 Then ' Do
        Set WB = ActiveWorkbook
        Set WS = ActiveSheet
        Set R = Selection
        HA = R.HorizontalAlignment
    Else ' Undo or Redo
        WB.Activate
        WS.Activate
        R.Select
    End If
    sProc = ThisWorkbook.Name & "!" & sName
    If Action >= 0 Then ' Do or Redo
        R.HorizontalAlignment = xlHAlignCenterAcrossSelection
        Application.OnUndo ("Undo " & sName), (sProc & "_Undo")
    Else ' Undo
        R.HorizontalAlignment = HA
        Application.OnRepeat ("Redo " & sName), (sProc & "_Redo")
    End If
End Sub

Private Sub CenterAcross_Undo()
    CenterAcross_Do Action:=-1 ' Undo
End Sub

Private Sub CenterAcross_Redo()
    CenterAcross_Do Action:=1 ' Redo
End Sub

See https://sites.google.com/view/MyExcelToolbox

This is only useful if your selection is contiguous with multiple adjacent cells in the same row but only one non-blank cell in that row. The selection can include more than one row, but each row should satisfy the previous condition. For each such row, the centering begins with the non-blank cell.