Mouse Click Event in VBA

"Supriyo asked if there is a mouse event handler in VBA. He wants a value inserted in a cell when that cell is clicked on." But he didn't specify the type of mouse click. There are two worksheet mouse click event handlers: Double-click and Right-click.

When a cell is double-clicked using the left mouse button it normally initiates Enter/Edit mode for typing into the cell. An alternate method is to select the cell (or left-click it) and press F2 (or simply start typing). If Supriyo wants cell B5 to contain the value 10 whenever that cell is double-clicked, he can add the following code to the applicable Sheet module:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, _
    Cancel As Boolean)
    If Intersect(Target, Range("B5")) Is Nothing Then Exit Sub
    Range("B5").Value = 10
    Cancel = True 'do not initiate Enter/Edit mode
End Sub

Right-clicking a cell normally opens its context menu. An alternate method is to select the cell (or left-click it) and press the Menu key (usually right of the Space bar). If Supriyo wants cell B5 to contain the value 10 whenever that cell is right-clicked, he can add the following code to the applicable Sheet module:

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, _
    Cancel As Boolean)
    If Intersect(Target, Range("B5")) Is Nothing Then Exit Sub
    Range("B5").Value = 10
    Cancel = True 'do not open the context menu
End Sub

It is not necessary to disable events when using these event handlers.

Once you add Event Macros to your workbook, you will need to consider disabling and enabling Events when running macros eg without it in the case below the updating of B5 could very well trigger a Worksheet_Change event macro to run.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Address = Range("B5").Address Then
Application.EnableEvents = False
Range("B5").Value = 10
Application.EnableEvents = True
End If
End Sub