Counting Empty Colored Cells

The Tip says its macros "don't take conditional formats into account at all." My comment dated 2024-05-27 included two macros named CountEmptyColored and CountBlankColored. To account for conditional formats as well as fill formats in each of those macros, simply replace the following statement
        With c.Interior
with this statement
        With c.DisplayFormat.Interior
Similar changes could be made to the Tip's macros.

Re. the first two paragraphs of my most recent comment below:
"Define an empty cell as one with no content and a blank cell as one that appears empty but might have content. A blank cell might be empty or it might contain a single apostrophe (') or a space character or a formula that returns null text (""), etc.
"The Range.SpecialCells(xlCellTypeBlanks) method returns empty cells only; blank cells are not included despite the name."
When c is a Range object representing a single cell, VBA's IsEmpty(c) function returns True for an empty cell and False for a blank cell that is not empty. Therefore, the Tip's use of IsEmpty(c) in its macros is superfluous.
Excel's ISBLANK function returns TRUE for an empty cell and FALSE for a blank cell that is not empty; therefore, it should be named ISEMPTY.
Notice Excel's WorksheetFunction object does not include an IsBlank method because that would duplicate VBA's IsEmpty function.
Using the above definitions of blank and empty, My Excel Toolbox includes the following two functions:
=IsCellBlank(Target)
=IsCellEmpty(Target)
IsCellBlank returns TRUE if Target is blank, FALSE if not.
IsCellEmpty returns TRUE if Target is empty, FALSE if not.
If Target is a contiguous range with more than one cell, an array is returned with TRUE/FALSE corresponding to each cell in Target.
See https://sites.google.com/view/MyExcelToolbox/

Define an empty cell as one with no content and a blank cell as one that appears empty but might have content. A blank cell might be empty or it might contain a single apostrophe (') or a space character or a formula that returns null text (""), etc.
The Range.SpecialCells(xlCellTypeBlanks) method returns empty cells only; blank cells are not included despite the name.
Here's a version of the Tip's CountBlankColors2 that counts empty colored cells as requested by Cindy.

Sub CountEmptyColored()
    Dim c As Range, x As Long
    x = 0
    On Error GoTo Done
        ActiveSheet.UsedRange.SpecialCells(xlCellTypeBlanks).Select
    On Error GoTo 0
    For Each c In Selection
        With c.Interior
            If .Pattern = xlSolid Then
                If .ColorIndex <> xlAutomatic Then x = x + 1
            ElseIf .Pattern <> xlNone Then
                x = x + 1
            End If
        End With
    Next c
Done: MsgBox "Number of empty colored cells: " & x
End Sub

Here's a version that counts blank colored cells, which Cindy might prefer.

Sub CountBlankColored()
    Dim c As Range, x As Long
    x = 0
    ActiveSheet.UsedRange.Select
    For Each c In Selection
        If Trim(c.Value) = "" Then
            With c.Interior
                If .Pattern = xlSolid Then
                    If .ColorIndex <> xlAutomatic Then x = x + 1
                ElseIf .Pattern <> xlNone Then
                    x = x + 1
                End If
            End With
        End If
    Next c
    MsgBox "Number of blank colored cells: " & x
End Sub

Notice UsedRange includes cells with a fill color or pattern. A cell with a pattern will have a color and vice versa. But if the pattern is solid and the color is automatic, the cell will have the normal background color and appear to have no color; such cells are not counted in these macro versions but are counted by the Tip's macros. Finally, xlPatternNone and xlColorIndexNone are the same as xlNone, xlPatternSolid is the same as xlSolid, and xlColorIndexAutomatic is the same as xlAutomatic.

Re. my previous comment below, SpecialCells(...) is a method, not a property.

The following statement should be added to the Tip's CountBlankColors1 macro
    Dim sTemp As String
In both macros, the following statement
ActiveSheet.Range("a1").CurrentRegion.SpecialCells(xlCellTypeBlanks).Select
probably should be replaced by this statement
    ActiveSheet.Range("a1").SpecialCells(xlCellTypeBlanks).Select
but the result might be the same.
Notice when cells in the range A1:B2 are blank (empty), the following statement
    ActiveSheet.Range("a1").CurrentRegion.Select
selects only cell A1 even if cells beyond A1:B2 are not blank. The property SpecialCells(...) apparently extends this selection beyond CurrentRegion to UsedRange.