Displaying Worksheets in a Slideshow Fashion

Barbara is trying to find a way to display several worksheets, one after another, almost like a slideshow. All the worksheets are in the same workbook. She wants each worksheet to show for 5-10 seconds, then automatically jump to the next worksheet and show for 5-10 seconds, and so on. The concept is to keep everything live and people can view it on a monitor by just waiting for their worksheet to pop up.

This is relatively easy to do by relying on the .Wait method to pause your macro for a specified length of time. All you need to do is to step through the display of each worksheet with the pause between each display. The following macro will accomplish the task:

Sub SlideShow1()
    Dim dDelay As Date
    Dim w As Worksheet

    dDelay = TimeValue("00:00:08")

    For Each w In Worksheets
        DoEvents
        w.Activate
        Application.Wait (Now() + dDelay)
        DoEvents
    Next w
End Sub

The macro pauses for eight seconds, but you can change the length of time in the line that assigns a value to the dDelay variable. Note that the macro also uses the DoEvents function a couple of times in the display loop so that you can, if desired, press Ctrl+C to break out of the macro.

Note that the macro only steps through the Worksheets collection once. If you want to do so multiple times, you can either restart the macro once it is done, or you can modify the macro so that the For Each loop is contained within an outer For Next loop that controls the number of times through the Worksheets collection.

Note, as well, that the macro simply steps through the worksheets, but this may not give you the result you want. The Worksheets collection is not guaranteed to be in any particular order, so what you see may be worksheets that aren't in your desired order. A better approach may be to specify the exact order you want. The following variation of the macro accomplishes this:

Sub SlideShow2()
    Dim dDelay As Date
    Dim J As Integer
    Dim iCnt As Integer
    Dim sNames(19) As String

    sNames(1) = "Sheet3"
    sNames(2) = "Sheet1"
    sNames(3) = "Sheet2"
    sNames(4) = "Sheet1"
    sNames(5) = "Sheet5"
    iCnt = 5

    dDelay = TimeValue("00:00:08")

    For J = 1 To iCnt
        DoEvents
        Worksheets(sNames(J)).Activate
        Application.Wait (Now() + dDelay)
        DoEvents
    Next J
End Sub

The macro takes a bit more to set up, as you need to assign worksheet names into the sNames array. (These need to be spelled exactly, as they appear on the worksheet tabs.) Place them in the order desired, and you can even repeat a worksheet multiple times, as is done with . The iCnt variable then should be set to the number of worksheet names in the sNames array. The display loop then steps through the array and displays each specified worksheet, in turn.

If you want to get fancier with your slideshow, you might want to consider taking screen shots of your worksheets and then putting those screen shots into a Powerpoint presentation.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13862) applies to Microsoft Excel .