Counting Values within 10% of a Target

Mike has a column in his worksheet that contains numeric values. Some are static values, while others are the result of formulas. He needs a count of all values in the column that are within 10% of a target value. So, if the target value is 5, then Mike needs a count of all values in the column that are between 4.5 and 5.5.

This can be done with the COUNTIFS function, which counts the number of values that match multiple criteria. In generating a count, it doesn't really matter if the values in the column are static or generated by a formula. Here, for instance, is a formula that will produce the count that Mike needs:

=COUNTIFS(A:A,">=4.5",A:A,"<=5.5")

The COUNTIFS function requires "pairs" of parameters, with the first one being the range to be evaluated and the second being the comparison that needs to be used against the range. So, in this instance, all the values in column A are compared to see if they are greater than or equal to 4.5 and the same range is compared to see if the values are less than or equal to 5.5.

You can make the formula more flexible by using the desired target value and calculating the 10% below and above, in this manner:

=COUNTIFS(A:A,">="&5*0.9,A:A,"<="&5*1.1)

In this case, notice that the comparison can be considered TRUE (and thus included in the count) if the value is inclusively between 4.5 and 5.5. If you prefer that the match not be inclusive, then you simply have to change the comparison operator:

=COUNTIFS(A:A,">"&5*0.9,A:A,"<"&5*1.1)

You could, of course, replace the in-formula target value with a cell reference that would, in turn, contain the target value:

=COUNTIFS(A:A,">"&B1*0.9,A:A,"<"&B1*1.1)

There are other approaches you can use besides the COUNTIFS function, if you prefer. For instance, either of the following will work just fine, once the target value is in cell B1:

=SUMPRODUCT((A:A>=B1*0.9)*(A:A<=B1*1.1))
=SUM(--(ABS(A:A/B1-1)<=0.1))

If you are using an older version of Excel (older than Excel 2021 or the Excel in Microsoft 365), then you'll need to enter these as array formulas using Ctrl+Shift+Enter.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (6070) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365.