Properties for Worksheets

The Tip's event handler clears the Undo stack each time a change is made to any sheet in the workbook; therefore, it is impossible to Undo (Ctrl+Z) any change.
On the other hand, the procedures described in my previous comment below preserve (do NOT clear) the Undo and Redo stacks; Ctrl+Z will Undo any change.
For more on this subject, see my recent comment here:
https://excelribbon.tips.net/T012513#comment-form-hd

The Tip's macro refers to ws.CustomProperties.Creator, which is the same as ws.Creator and Application.Creator. The Excel value is 1480803660 (&H5843454C); those 8 hexadecimal values represent the 4 ASCII characters XCEL.
Each worksheet can have its own custom properties. The following ThisWorkbook event handlers store created and modified date, time, and user information for each worksheet as custom property text:

Private Sub Workbook_NewSheet(ByVal Sh As Object)
    If TypeOf Sh Is Worksheet Then
        Sh.CustomProperties.Add Name:="Created", Value:=CPValue()
    End If
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    Dim oCP As CustomProperty
    If TypeOf Sh Is Worksheet Then
        For Each oCP In Sh.CustomProperties
            If oCP.Name = "Modified" Then oCP.Delete: Exit For
        Next oCP
        Sh.CustomProperties.Add Name:="Modified", Value:=CPValue()
    End If
End Sub

Private Function CPValue() As String
    CPValue = FormatDateTime(Date, vbShortDate) _
        & " " & FormatDateTime(Time, vbLongTime) _
        & " by " & Application.UserName
End Function

Notice "Created" information is only available for worksheets added after implementing the NewSheet event handler. "Modified" information is updated after any worksheet is changed. Each worksheet's custom properties are retained when the workbook is saved.
The following macro will report "Created" and "Modified" information for the active worksheet:

Sub CreatedModified()
    Dim oCP As CustomProperty, sCreated As String, sModified As String
    If TypeOf ActiveSheet Is Worksheet Then
        sCreated = "(unknown)"
        sModified = sCreated
        For Each oCP In ActiveSheet.CustomProperties
            Select Case oCP.Name
            Case "Created": sCreated = oCP.Value
            Case "Modified": sModified = oCP.Value
            End Select
        Next oCP
        MsgBox "This worksheet was created" & vbLf & sCreated & vbLf _
            & vbLf & "This worksheet was modified" & vbLf & sModified
    Else
        MsgBox "The active sheet is not a worksheet"
    End If
End Sub

My Excel Toolbox includes the following function to return the value of a custom worksheet property:
    =GetCustomWSProperty(Name, [Sheet])
Name's case is ignored if custom worksheet property Name exists; otherwise, #VALUE! error is returned.
If optional Sheet is omitted, the custom property applies to the formula cell's worksheet; otherwise, it applies to the specified Sheet (case ignored) in that cell's workbook. Therefore, these formulas will return "Created" and "Modified" information for the active worksheet:
    =GetCustomWSProperty("Created")
    =GetCustomWSProperty("Modified")
Press F9 to update those results.
The following dynamic array function lists any custom worksheet properties:
    =ListCustomWSProperties([AllSheets], [SkipHeader])
If AllSheets is FALSE (default), only the formula cell's worksheet will be evaluated; otherwise, all worksheets in the workbook are included. Therefore, the following formula provides an alternative to the Tip's "Stats" worksheet:
    =ListCustomWSProperties(TRUE)
Again, press F9 for the latest results.
The SpillArray function (described in UseSpillArray.pdf) simulates a dynamic array in older versions of Excel.
See https://sites.google.com/view/MyExcelToolbox