Changing Width and Height to Inches

Dean wonders how to change the column width and the row height from pixels to inches. He would like to create labels in Excel, and they are specified in inches.

Before getting into possible ways to address this problem, it should be pointed out that Excel uses an odd way of calculating row height and column width. In fact, row height is calculated entirely differently than is column width.

Row height is measured not in pixels, but in points. A pixel is a relative unit of measurement related primarily to display devices such as monitors and printers. If something is 50 pixels wide, that size, by itself, means nothing without knowing how many pixels the device is capable of displaying vertically.

Points, however, are well defined—there are approximately 72 points per inch, so a row height of 72 would be an inch tall. Simple, right?

Now consider column width, which is not specified either by pixels or points. Instead, it is specified in character widths of whatever typeface you are using. For instance, if your Standard style is set to Courier 10, then a column width of 12 means you can fit exactly 12 characters in a given column. Change the typeface used, and all of a sudden, your column width will change, as well, so that it can still display 12 characters.

Yes, that approach is really goofy. It also makes it very hard to do something like design labels in Excel. You might get something designed that works on your system (after a good deal of trial and error), but if you then forward the workbook off to a friend, chances are good that it won't work on their system. Why? Because how a typeface is rendered on their system may differ entirely than it does on yours.

The best way to deal with labels, quite honestly, is to do them in Word. You can keep your label data in an Excel worksheet, but use mail merge in Word to create the actual labels. The tools provided for labels are much easier and much more precise than what you can do in Excel.

If you absolutely must do it in Excel, then you should switch to Page Layout view. (Display the View tab of the ribbon and click the Page Layout tool in the Workbook Views group.) This displays both horizontal and vertical rulers on the screen that you can use as a guide to help set your row height and column widths.

There is another interesting side-effect of working in Page Layout view: If you display the Home tab of the ribbon and use the commands for setting row height and column width (from the Format tool), you'll note that both are specified in inches. They only go back to the absurd character-count column width if you switch back to Normal view.

If you prefer to set the height and width through the use of a macro, you might find the WidthHeightInches macro instructive.

Sub WidthHeightInches()
    Dim Temp As String
    Dim RInch As Single
    Dim CInch As Single
    Dim WPChar As Double
    Dim c As Range
    Dim r As Range

    Temp = InputBox("Row height in inches?")
    RInch = Val(Temp)
    If RInch > 0 And RInch <= 2 Then
        Temp = InputBox("Column width in inches?")
        CInch = Val(Temp)
        If CInch > 0 And CInch <= 3 Then
            For Each c In ActiveWindow.RangeSelection.Columns
                WPChar = c.Width / c.ColumnWidth
                c.ColumnWidth = ((CInch * 72) / WPChar)
            Next c
            For Each r In ActiveWindow.RangeSelection.Rows
                r.RowHeight = (RInch * 72)
            Next r
        End If
    End If
End Sub

Remember that column widths are specified by the number of digits that can be fit horizontally in a cell. The heart of this macro figures out the width of a single digit, in points. It does this by dividing the width of the column in points (the .Width property) by the width of the column in characters (the .ColumnWidth property). This value is then used to calculate how many characters wide the column should be in order to be the width desired.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (8768) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and Excel in Microsoft 365.