Counting Words

Words are normally associated with a word processor, such as Microsoft Word. However, many people also work with words in their spreadsheet program. (I had a coworker once who used Excel to write memos all the time.) There may be times when you want to count the number of words in a worksheet that you receive from someone. There are native abilities to perform such a task in Word, but not in Excel.

One solution, of course, is to load your workbook into Word, perform the word count there, and then close the file. This is not nearly as flexible, however, as creating a macro to count words within Excel itself. The following macro, CountWords, counts the number of words in any range you select in a worksheet:

Sub CountWords()
    Dim lWords As Long
    Dim Raw As String
    Dim c As Range

    lWords = 0
    For Each c In Selection
        If Not c.HasFormula Then
            ' Get text in cell
            Raw = c.Value
            ' Get rid of extra spaces before, after, and within text
            Raw = Application.Trim(Raw)
            ' Get rid of any manual line breaks
            ' and don't assume that they represent the start
            ' of a new word
            Raw = Replace(Raw, Chr(10), "")
            ' Now count spaces in remaining text
            lWords = lWords + Len(Raw) - Len(Replace(Raw, " ", ""))
            ' Always increment word count if there is something in
            ' the cell. If, however, there is nothing there, then
            ' don't add a word.
            If Len(Raw) > 0 Then lWords = lWords + 1
        End If
    Next c
    MsgBox "There are " & lWords & " words in the selection."
End Sub

Notice that the macro steps through each cell in the range you select. It then ignores any cell that contains a formula. In all other cells it essentially counts the number of spaces in the cell. (One or more spaces are assumed to separate words.) Note, as well, that the Trim worksheet function is used instead of the VBA Trim function. The reason is because the worksheet version gets rid of extra spaces in the middle of the text, whereas the VBA function gets rid of only leading or trailing spaces. The word count is then displayed in a message box for your edification.

The macro is very quick on relatively small ranges. If you pick a large range (such as the entire worksheet), then the macro can take a great deal of time to finish its work. The point of this is to make sure that you only select the actual range you want to analyze before invoking the macro.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (11748) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365. You can find a version of this tip for the older menu interface of Excel here: Counting Words.