Copying Headers and Footers

Excel allows you to specify headers and footers for your worksheets. You may want to copy these headers and footers from one worksheet to another. Doing so within a workbook is relatively easy, but doing so from one workbook to another can be more daunting.

If the header and footer is one you use quite a bit in new workbooks, and your main concern is to have the header and footer available in those new workbooks (not in existing workbooks), then the best approach would be to create a template workbook. Just set up a workbook as desired, including the specification of headers and footers. Then, save the workbook as an Excel template (XLTX format). You can then create your workbooks based on this template and it will have the headers and footers you desire.

One way to copy headers and footers from a worksheet in one workbook to a worksheet in another is to use the traditional editing methods of copying and pasting. In other words, you can select the header material you want to copy, press Ctrl+C, display the header in the target worksheet, and then press Ctrl+V. The drawback to this approach is that it can involve quite a few steps. After all, there are three sections (left, center, and right) for each header and three for each footer. This means that you must do six copy and paste operations to copy the complete header and footer.

Another way to copy headers and footers from one workbook to another involves the use of native Excel commands to make copies of worksheets. Follow these steps:

1. Open the target workbook; the one to which you want the headers and footers copied.
2. Open the workbook that is the source of your header and footer, and make sure the desired worksheet is displayed.
3. Display the Home tab of the ribbon.
4. Click the Format tool (in the Cells group) and then choose Move or Copy Sheet. Excel displays the Move or Copy dialog box. (See Figure 1.)



Figure 1. The Move or Copy dialog box.

5. Using the To Book drop-down list, select the target workbook you opened in step 1.
6. Using the Before Sheet area, indicate where you want the sheet copied.
7. Make sure the Create a Copy check box is selected.
8. Click on OK. The worksheet is copied to the target workbook.
9. Close the source workbook from step 2.
10. In the target workbook, display the worksheet you just copied.
11. In the tab area at the bottom of the window, right-click and choose Select All Sheets. All the worksheets are now selected.
12. Display the Page Layout tab of the ribbon.
13. Click the small icon at the lower-right corner of the Page Setup group. Excel displays the Page Setup dialog box.
14. Make sure the Header/Footer tab is selected. (See Figure 2.)



Figure 2. The Header/Footer tab of the Page Setup dialog box.

15. Using the Header and Footer drop-down lists, select the header and footer used in the worksheet you just copied.
16. Click on OK.
17. Delete the worksheet you copied in steps 1 through 8.

What you essentially did is to copy the worksheet containing the header and footer you desired, then you copied that header and footer to other worksheets in the workbook, then you deleted the original worksheet.

While these steps work fine, they can be tedious if you need to copy headers and footers to a number of different workbooks. In this case, using a macro to do the copying is the saner approach. The following two macros can be used to copy headers and footers in one simple step. All you need to do is display the source worksheet and use the GetHeaders macro. This macro copies the header and footer information to string variables. You can then display, in turn, each worksheet that you want to have the same header and footer and run the DoHeaders macro.

Option Explicit

Dim strHeadLeft As String
Dim strHeadCenter As String
Dim strHeadRight As String
Dim strFootLeft As String
Dim strFootCenter As String
Dim strFootRight As String
Dim bGotHeaders As Boolean

Sub GetHeaders()
    With ActiveSheet.PageSetup
        strHeadLeft = .LeftHeader
        strHeadCenter = .CenterHeader
        strHeadRight = .RightHeader
        strFootLeft = .LeftFooter
        strFootCenter = .CenterFooter
        strFootRight = .RightFooter
        bGotHeaders = True
    End With
End Sub

Sub DoHeaders()
    If bGotHeaders Then
        With ActiveSheet.PageSetup
            .LeftHeader = strHeadLeft
            .CenterHeader = strHeadCenter
            .RightHeader = strHeadRight
            .LeftFooter = strFootLeft
            .CenterFooter = strFootCenter
            .RightFooter = strFootRight
        End With
    Else
        MsgBox "Select the sheet with the " _
            & "headers you want to copy," _
            & vbCrLf & "then run 'GetHeaders'", _
            vbExclamation, "No Headers In Memory"
    End If
End Sub

You could even assign the macros to toolbar buttons or to the Quick Access toolbar, if desired, which can make them even handier for copying headers and footers.

If you have quite a few worksheets and workbooks into which you want the headers and footers copied, there is a different macro approach you can use. The following macro will copy the headers and footers from the active worksheet to all other worksheets in all other open workbooks.

Sub CopyHeaderFooter()
    Dim PS As PageSetup
    Dim WB As Workbook
    Dim WS As Worksheet

    Set PS = ActiveSheet.PageSetup
    For Each WB In Workbooks
        For Each WS In WB.Worksheets
            With WS.PageSetup
                .LeftHeader = PS.LeftHeader
                .CenterHeader = PS.CenterHeader
                .RightHeader = PS.RightHeader
                .LeftFooter = PS.LeftFooter
                .CenterFooter = PS.CenterFooter
                .RightFooter = PS.RightFooter
            End With
        Next
    Next
End Sub

In other words, if you want to copy headers and footers from the current worksheet to 150 other worksheets spread across 15 different workbooks, all you need to do is open the 15 workbooks at the same time, display the source worksheet, and run the macro.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (12519) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365. You can find a version of this tip for the older menu interface of Excel here: Copying Headers and Footers.