Changing Comment Color for a Single User

Mikki is looking for a way to change the default color on worksheet comments so that she can tell her comments apart from comments made by other people.

When you add a comment to a cell in a worksheet, Excel allows you to change the formatting used for that comment. Once the comment is created, follow these steps:

1. Right-click on the cell and choose Edit Comment from the Context menu. This places the insertion point within the comment where you can type more information, if desired.
2. Right-click on the comment's border and select Format Comment from the resulting Context menu. Excel displays the Format Comment dialog box.
3. Use the controls in the dialog box to change how you want the comment to appear.
4. Click OK.

These steps are all fine and good, but they affect only the current comment. If you want to set a default for any comments you add in the future, Excel doesn't remember your formatting and it provides no way to make a change to the defaults. Instead, Excel grabs its default comment formatting from Windows itself. You can modify this by changing the display properties for Windows, specifically the ToolTip display setting. If you modify this, then you have modified how Excel formats your comments. (You've also modified how ToolTips appear in every other program on your system, as well.)

A workaround is to use a macro to insert your comments. The macro can not only insert the comment, but also format it according to your needs. Here's an example of a short macro that will insert a comment for the selected cell and, if the user's name is "Mikki," make the background color turquoise. (The user's name is defined in the setup for Excel.)

Sub AddMyComment()
    Dim sUserName As String
    Dim  addr As String

    sUserName = Application.UserName

    With ActiveCell
        addr = .Address

        If sUserName = "Mikki" Then
            ActiveSheet.Range(addr).AddComment
            Range(addr).Comment.Shape.Select True
            Selection.ShapeRange.Fill.ForeColor.SchemeColor = 41
        Else
            Range(addr).AddComment
        End If
    End With
End Sub

If you already have a worksheet that contains many comments, you might want to look for comments that have the text "Mikki" within them and then change the color of those comments. This macro fits the bill:

Sub ColorMyComments1()
    Dim myCom As Comment

    For Each myCom In ActiveSheet.Comments
    If InStr(myCom.Text, "Mikki") <> 0 Then
        myCom.Shape.Fill.ForeColor.SchemeColor = 41
    End If
    Next myCom
End Sub

Understand that the macro will change the color if the text "Mikki" appears anywhere within the comment text. A slight variation of the macro checks the comment's Author attribute, and if it is set to "Mikki," then it makes the change:

Sub ColorMyComments2()
    Dim myCom As Comment

    For Each myCom In ActiveSheet.Comments
    If myCom.Author = "Mikki" Then
        myCom.Shape.Fill.ForeColor.SchemeColor = 41
    End If
    Next myCom
End Sub

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (12567) applies to Microsoft Excel 2007, 2010, and 2013.