Trimming Spaces from Strings

My Excel Toolbox now includes the TextSpaceChars macro to convert all UNICODE space characters (see Figure 1 below) into standard ASCII space without disturbing the format of individual characters. This macro applies to text constants within the current Selection. Undo (Ctrl+Z) is supported.
See https://sites.google.com/view/MyExcelToolbox/

@sandeep kothari
If you use Alex Blakenburg's code:
    arr = Selection.Value
    arr = Application.Substitute(arr, ChrW(160), "")
    Selection.Value = arr
Make sure Selection does not include any formula cells because formulas will be replaced with constants (similar to Paste Values).

Thanks a lot for the valuable guidance, Woolley & Alex. These have made my day.

@sandeep kothari, in terms of VBA.
Working directly with a range:-
Selection.Replace what:=ChrW(160), replacement:=""
If you are putting the range into an array for further processing then:-
Dim arr As Variant

arr = Selection.Value
arr = Application.Substitute(arr, ChrW(160), "")
Selection.Value = arr

@sandeep kothari
If cell A1 contains non-breaking space characters, try this:
=TRIM(SUBSTITUTE(A1,UNICHAR(160),CHAR(32)))
Repeat SUBSTITUTE(...) for any additional non-standard space characters like UNICHAR(8199) or UNICHAR(HEX2DEC("2007")).
See https://unicode-explorer.com/articles/space-characters
If A1 is replaced by a range array like A1:A9, a dynamic array is returned by Excel 2021+.

Nice codes, Allen, Woolley & Alex. What is the code to delete other spaces, like CHAR 32, 160, etc?

My Excel Toolbox includes the following functions useful in cell formulas:
    =TrimHead(Text, [NumChars])
    =TrimTail(Text, [NumChars])
TrimHead trims leading characters from Text and returns the result. If optional NumChars < 1 (default), all leading space characters are trimmed; otherwise, NumChars leading characters are trimmed.
TrimTail is analogous except it trims trailing characters.
Here are abbreviated versions:

Function TrimHead(Text As String, Optional NumChars As Integer) As String
    If NumChars < 1 Then
        TrimHead = LTrim(Text)
    Else
        TrimHead = Mid(Text, (NumChars + 1))
    End If
End Function

Function TrimTail(Text As String, Optional NumChars As Integer) As String
    If NumChars < 1 Then
        TrimTail = RTrim(Text)
    Else
        Dim n As Integer
        n = Len(Text) - NumChars
        If n > 0 Then TrimTail = Left(Text, n) 'else return null default
    End If
End Function

My Excel Toolbox also includes the TextTrim macro to remove ALL extra spaces (begin, middle, end; like TRIM) from text constants in Selection without disturbing the format of individual characters. Here is an abbreviated version:

Sub TextTrim()
    Dim rText As Range, rCell As Range
    Dim sText As String, sTrim As String, nTrim As Integer, n As Integer
    On Error Resume Next
        'Intersect is necessary in case Selection.Cells.Count = 1
        Set rText = Intersect(Selection, _
            Selection.SpecialCells(xlCellTypeConstants, xlTextValues))
    On Error GoTo 0
    If rText Is Nothing Then
        MsgBox "There are no text constants in Selection", vbCritical
        Exit Sub
    Else
        rText.Select
        rText.Cells(1).Show
    End If
    For Each rCell In rText
        sText = rCell.Value
        sTrim = Application.WorksheetFunction.Trim(sText)
        nTrim = 1
        For n = 1 To Len(sText)
            If Mid(sText, n, 1) = Mid(sTrim, nTrim, 1) Then
                nTrim = nTrim + 1
            Else
                rCell.Characters(nTrim, 1).Delete
            End If
        Next n
    Next rCell
End Sub

The unabbreviated version of TextTrim supports Undo (Ctrl+Z).
See https://sites.google.com/view/MyExcelToolbox

One of the things I love about Application.Trim is that it can take a range or an array as the argument, so you don't need to loop through the Range or Array eg
ActiveSheet.UsedRange.Value = Application.Trim(ActiveSheet.UsedRange.Value)