Printing in Black and White and Color

Ken has a workbook containing 30 worksheets. He would like to print sheets 1 through 29 in black and white and sheet 30 in color. He wonders if there is a way to print all the worksheets at once and specify that a particular worksheet should print in color only.

This is easiest done with a macro. All it takes is to set the .BlackAndWhite property for each worksheet just before it is printed. For instance, consider the following simple macro:

Sub PrintSingleColorSheet()
    Dim w As Worksheet
    Dim S As Integer

    ' Set worksheet to be in color
    ' (All others will print in B/W)
    S = 30

    For Each w In Worksheets
        w.PageSetup.BlackAndWhite = True
        If w.Index = S Then
            w.PageSetup.BlackAndWhite = False
        End If
        w.PrintOut
    Next w
End Sub

The macro stores in the S variable the index number of the worksheet you want to be in color. (In this case, the index number is 30.) Then, each worksheet is stepped through and the .BlackAndWhite property set to True. If, however, the .Index property for the worksheet matches the value stored in S, then the .BlackAndWhite property is set to False, meaning it will print in color. The printout is then sent to the default printer.

You could, if you wanted, get fancier with the macro, meaning you could have it ask the user which worksheet to print in color:

Sub PrintSingleColorSheet()
    Dim w As Worksheet
    Dim S As Integer
    Dim sTemp As String
    Dim sMsg As String

    sMsg = "There are " & Worksheets.Count & " worksheets in this "
    sMsg = sMsg & "workbook. Please enter the number of the single "
    sMsg = sMsg & "worksheet you want to print in color. (All "
    sMsg = sMsg & "others will print in black and white.)"

    sTemp = InputBox(sMsg)
    S = Val(sTemp)
    If S > 0 And S <= Worksheets.Count Then
        For Each w In Worksheets
            w.PageSetup.BlackAndWhite = True
            If w.Index = S Then
                w.PageSetup.BlackAndWhite = False
            End If
            w.PrintOut
        Next w
    Else
        sMsg = "You entered a value that is out of range."
        If sTemp <> "" Then
            MsgBox sMsg
        End If
    End If
End Sub

This version of the macro asks the user to input a worksheet number. If the value entered is out of range, then an error message is displayed, and the macro doesn't print anything. If the user clicks Cancel or leaves the input box empty, then the macro simply exits without printing anything.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13738) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and Excel in Microsoft 365.