Working in Feet and Inches

May be Microsoft will decide to implement feet and inches format. Conversion to metric system is not likely to happen anytime soon, After all, we all still use Babylonian format for the time, and it is not changing to some metric/decimal system either. Having said that, a format showing length in feet, inches and fractions shouldn't be harder to devise than the format showing time as dd/MM/yyyy hh:mm:ss.s. It deals well with varying lengths of months, leap years and even has a variation to show elapsed time: [h]:mm:ss

Similarly you could have a format like F'II #/#" for feet inches and fractions
and {I} #/# for inches and fractions.

For now best you can do is what @Michael Armstrong suggested: do all your calculations in inches and fractions, and convert the results to feet inches and fractions when needed. And see my previous comment about entering inches and fractions easily.

To expand on that last thought, if you stick to just halfs, quarters, eighths, sixteenths, etc. all results of addition subtraction and multiplication by a number will have only these fractions. And with proper format they will be rounded to the smallest possible denominator, hence you will not see something like 5 8/16 but 5 1/2. A good format for this is "# #/??" for up to two digits in the denominator, or "# #/???" for up to three-digits denominator.

Did you know that if you type in a number into an unused cell using fractional format, like "2 3/8", Excel will auto-format that cell in fractional format?
That may work well for inches and fractions. but for feet and inches, entering "5 4/12" will be displayed as "5 1/3". it may be not what you wanted. You can manually set fractions to always display as twelfths using format"# #/12" for inches and feet.

For feet, inches, and fractions, Excel doesn't have any built-in math. But such arithmetic exists in many CAD programs, so may be it could be implemented in Excel as well.

@J-M J

Metric conversion would be great, but won't happen soon.

I live in Canada (a metric country), and I came from Poland (another metric country). In Canada feet and inches are fully alive, but so are pounds (most grocery prices are given per pound, except on the receipt at the register, where they are per kg; that keeps your arithmetic skills alive).
I got used to some of those, but to make things more varied we use degrees Celsius for weather, but Fahrenheit for cooking. And don't start me on the date formats.

Even in Poland quite a few years ago I was buying some particle boards. They were 1219 mm x 2438 mm! I wondered why. Guess what, that is 4ft x 8 ft.

What about the "Metric Conversion Act" of 1975? Definitively buried under feet and inches of habits?

Your formula for displaying inches as feet and inches works great for positive values, but fails pretty miserably for negative values. For example, using a value of 80 inches gives a result of 6'8" as expected, but using a value of -80 inches results in -7'4" - a pretty large discrepancy!

As inconvenient as it is to have to account for that, a better formula would be:
=IF(A1>=0, FLOOR.MATH(A1/12), CEILING.MATH(A1/12)) & "'" & IF(A1>=0, MOD(A1, 12), MOD(-A1, 12)) & """"

This handles positive and negative values correctly.

I enjoy reading your comments Willy. You always speak a lot of sense and simplify the problem!

What am I happy to live in a country using the metric system as do an overwhelming majority of the countries in the world.

This function I use to work with feet & inches. This will convert any dimension figure to show 0'-0 0/0" format.

Public Function FeetInch(Inch As Double, Optional Denominator As Integer = 16) As String
Dim Negative As Boolean
Dim FeetValue As Long
Dim InchValue As Long
Dim FractionValue As Double
Dim FractionReductionCount As Integer
Dim Numerator As Integer
Dim F As String, i As String, Fr As String

Application.Volatile

Negative = (Inch < 0)
If Negative Then Inch = Inch * -1

FeetValue = Int(Inch / 12)
InchValue = Int(Inch - FeetValue * 12)
FractionValue = Round((Inch - FeetValue * 12 - InchValue) * Denominator, 0) / Denominator
If FractionValue = 1 Then
FractionValue = 0
InchValue = InchValue + 1
End If

FractionReductionCount = 0
Numerator = FractionValue * Denominator
If FractionValue <> 0 Then
Do Until Int(Numerator / 2) <> Numerator / 2
Numerator = Numerator / 2
FractionReductionCount = FractionReductionCount + 1
Loop
End If

F = FeetValue & "'-"
If FeetValue = 0 Then F = ""

Fr = Numerator & "/" & Denominator / 2 ^ FractionReductionCount & """"
If FractionValue = 0 Then Fr = """"

i = InchValue & " "
If InchValue = 0 And FeetValue = 0 Then i = ""
If FractionValue = 0 Then i = Trim(InchValue)

FeetInch = IIf(Negative, "-", "") & F & i & Fr
End Function

This will convert feet & inch format 0'-0 0/0" to a number you can use in calculations.


Public Function Inch(ByVal FeetInch As String, Optional Rounding As Integer = 0) As Double
Dim Negative As Boolean
Dim Apos As Long 'Apostrophe
Dim Hpos As Long 'Hyphen
Dim Spos As Long 'Space
Dim Dpos As Long 'Divider
Dim Qpos As Long 'Quotation
Dim EndValue As Double

Dim FeetValue As Double
Dim InchValue As Double
Dim Numerator As Double
Dim Denominator As Double

Application.Volatile

If Left(FeetInch, 1) = "*" Then
FeetInch = [AddLongLength] & Right(FeetInch, Len(FeetInch) - 1)
End If

FeetValue = 0
InchValue = 0
Numerator = 0
Denominator = 1

If Left(FeetInch, 1) = "-" Then
Negative = (Left(FeetInch, 1) = "-")
FeetInch = Right(FeetInch, Len(FeetInch) - 1)
End If

Qpos = InStr(FeetInch, """") 'Quotation
If Qpos > 0 Then FeetInch = Left(FeetInch, Qpos - 1)

Dpos = InStr(FeetInch, "/") 'Divider
Spos = InStr(FeetInch, " ") 'Space
Hpos = InStr(FeetInch, "-") 'Hyphen
Apos = InStr(FeetInch, "'") 'Apostrophe

If Dpos > 0 Then 'Divider indicates fraction in string
Select Case True
Case Spos > 0 'Space
Numerator = CDbl(Mid(FeetInch, Spos + 1, Dpos - Spos - 1))
Denominator = CDbl(Mid(FeetInch, Dpos + 1))
FeetInch = Left(FeetInch, Spos - 1)
Case Hpos > 0 'Hyphen
Numerator = CDbl(Mid(FeetInch, Hpos + 1, Dpos - Hpos - 1))
Denominator = CDbl(Mid(FeetInch, Dpos + 1))
FeetInch = Left(FeetInch, Hpos - 1)
Case Apos > 0 'Apostrophe
Numerator = CDbl(Mid(FeetInch, Apos + 1, Dpos - Apos - 1))
Denominator = CDbl(Mid(FeetInch, Dpos + 1))
Case Else 'Fraction Only
Numerator = CDbl(Left(FeetInch, Dpos - 1))
Denominator = CDbl(Right(FeetInch, Len(FeetInch) - Dpos))
FeetInch = ""
End Select
End If

Hpos = InStr(FeetInch, "-") 'Hyphen

If Hpos > 0 Then
If Len(FeetInch) > Hpos Then
InchValue = CDbl(Right(FeetInch, Len(FeetInch) - Hpos))
FeetInch = Left(FeetInch, Hpos - 1)
End If
End If

Apos = InStr(FeetInch, "'") 'Apostrophe

If Apos > 0 Then
FeetValue = CDbl(Left(FeetInch, Apos - 1))
FeetInch = Right(FeetInch, Len(FeetInch) - Apos)
End If

If Len(FeetInch) > 0 Then InchValue = InchValue + CDbl(FeetInch)

If Rounding = 0 Then
EndValue = FeetValue * 12 + InchValue + Numerator / Denominator
Else
EndValue = Round((FeetValue * 12 + InchValue + Numerator / Denominator) * Rounding, 0) / Rounding
End If
If Negative Then
EndValue = EndValue * -1
End If

Inch = EndValue
End Function

I use these everyday in my work. I get field measurements from constructions site that I need to convert and use in various calculations.

Public Function FeetInch(Inch As Double, Optional Denominator As Integer = 16) As String
Dim Negative As Boolean
Dim FeetValue As Long
Dim InchValue As Long
Dim FractionValue As Double
Dim FractionReductionCount As Integer
Dim Numerator As Integer
Dim F As String, i As String, Fr As String

Application.Volatile

Negative = (Inch < 0)
If Negative Then Inch = Inch * -1

FeetValue = Int(Inch / 12)
InchValue = Int(Inch - FeetValue * 12)
FractionValue = Round((Inch - FeetValue * 12 - InchValue) * Denominator, 0) / Denominator
If FractionValue = 1 Then
FractionValue = 0
InchValue = InchValue + 1
End If

FractionReductionCount = 0
Numerator = FractionValue * Denominator
If FractionValue <> 0 Then
Do Until Int(Numerator / 2) <> Numerator / 2
Numerator = Numerator / 2
FractionReductionCount = FractionReductionCount + 1
Loop
End If

F = FeetValue & "'-"
If FeetValue = 0 Then F = ""

Fr = Numerator & "/" & Denominator / 2 ^ FractionReductionCount & """"
If FractionValue = 0 Then Fr = """"

i = InchValue & " "
If InchValue = 0 And FeetValue = 0 Then i = ""
If FractionValue = 0 Then i = Trim(InchValue)

FeetInch = IIf(Negative, "-", "") & F & i & Fr
End Function

My firm measures depths in feet, inches, and eighths for soil borings. Instead of having a separate column for feet, inches, and eighths, we designated the data entry column to be ft.in8, i.e., feet is the integer, the first two decimal positions are for inches, and the third decimal is for eighths of an inch. Thus, 10'-3 1/4" is entered as 10.032; 1'-0 5/8" is entered as 1.005. The header at the top of the column includes the data entry definition, (ft.in8). The next column in the spreadsheet, which could be hidden, converts the entered data to feet. This data entry alleviates the need to be entering an ', -, or " with the data, which slows down the data entry considerably. If we want the entered data to be presented in feet'-inch" format, than we have a data entry/computation worksheet and a second worksheet set up for printout.

Hmmm. I've been using Excel (now 365) for quite a while for doing construction calculations, and in my naïveté just mixed inches and feet routinely, converting and setting formats as required, and never noticed a problem. I'd do things like specify cutting boards to length in inches,and keeping track of those lengths in feet, to determine the number of, say, 12' boards required for all the boards to be cut.

How about working in twelfths - using custom formats "# ??/12" - if you enter a measurement as 4 5/12 for 4 feet 5 inches Excel converts it to decimals, does the maths and if the answer cell is similarly formatted with show the results in integer feet and fraction inches.

I worked with feet & inches forever - 1 inch = .083 -2 inches = .167 - 3 inches = .25 etc etc - what's the big deal ? just decimalize