Making Sure Cells are Filled In before Saving

Riley has a worksheet that he needs to work with every Friday. This worksheet is based on a template, and there are, at minimum, five cells he needs to fill in, in the range C4:C8. When he starts with the worksheet, these cells are blank. Riley wonders if there is a way to prevent the worksheet from being saved and/or closed until he fills in all five of these cells.

There is a way to do this, but it involves the use of macros. Excel supports the concept of event handlers, which means that you can develop macros that run, automatically, when certain events occur. Two events for which you can create special event handlers are BeforeClose (meaning, before the workbook closes) and BeforeSave (before the workbook is saved).

As an example of how this could work, let's say that the worksheet containing the range to be checked (C4:C8) is named "MyData." You could add this code to the ThisWorkbook module:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Dim rng As Range
    Dim iCount As Integer
    Dim sTemp As String

    Set rng = Worksheets("MyData").Range("C4:C8")
    iCount = Application.WorksheetFunction.CountBlank(rng)
    If iCount <> 0 Then
        sTemp = rng.Address & " has blank cells. " & vbCrLf
        sTemp = sTemp & "The workbook will not be closed."
        MsgBox sTemp
        Cancel = True
    End If
End Sub

Note that the macro relies on the CountBlank worksheet function to determine if there are any blanks in the range of cells. If it detects any blank cekks (iCount is greater than 0), then the macro displays a message to the user and the Cancel variable is set to True, which actually stops the workbook from closing.

You can use a similar macro for the BeforeSave event, in this manner:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim rng As Range
    Dim iCount As Integer
    Dim sTemp As String

    Set rng = Worksheets("MyData").Range("C4:C8")
    iCount = Application.WorksheetFunction.CountBlank(rng)
    If iCount <> 0 Then
        sTemp = rng.Address & " has blank cells. " & vbCrLf
        sTemp = sTemp & "The workbook will not be saved."
        MsgBox sTemp
        Cancel = True
    End If
End Sub

If you wanted to make sure that the routine selected the cells in which input is needed (as a final step), you could add the following line to both macros, right after the line that sets the Cancel variable to True:

        rng.Select

Remember, as well, that since your workbook is based on a template, it will need to be saved as a macro-enabled template in order to work properly.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (4364) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365.