Pasting a Graphic to Multiple Worksheets

Marty has a series of workbooks, some with as many as 50 worksheets. He needs to paste a graphic (a company logo) into the same spot on each worksheet. He tried to do this by selecting all the worksheets and then doing the pasting, but that didn't seem to work on multiple worksheets like regular editing does.

Marty is right; trying to paste a graphic when you have multiple worksheets selected doesn't work. When you try, Excel tells you that it cannot make the paste, but if you then select just a single worksheet you can paste quite nicely.

Instead, you need to use a macro to do the pasting. Assuming that the graphic has already been copied to the Clipboard, you can run a macro such as the following:

Sub InsertLogo1()
    Dim shtSheet As Worksheet

    Application.ScreenUpdating = False
    For Each shtSheet In Worksheets
        With shtSheet
            .Activate
            .Range("A1").Select
            .Paste
        End With
    Next
    Set shtSheet = Nothing
    Application.ScreenUpdating = True
End Sub

The macro steps through each worksheet in the workbook and pastes the graphic into cell A1. If you want to use a different cell, then all you need to do is modify the line that selects the cell.

If you don't want to copy the graphic to the Clipboard ahead of time, you can use a macro such as the following to insert the graphic directly from an image file:

Sub InsertLogo2()
    Dim strPath As String
    Dim shtSheet As Worksheet

    strPath = "C:\GraphicFolder\PictureName.bmp"

    For Each shtSheet In Worksheets
        shtSheet.Activate
        Range("A1").Select
        ActiveSheet.Pictures.Insert (strPath)
    Next shtSheet
    Set shtSheet = Nothing
End Sub

You can, of course, modify the path to the graphic file and the cell at which the file is pasted into the worksheets. If desired, you could use the following variation that displays a standard Windows dialog box to select the graphic you want to insert:

Sub InsertLogo3()
    Dim strPath As Variant
    Dim shtSheet As Worksheet
    Dim sTemp As String

    ' Set the file type
    sTemp = "Graphics Files (*.jpg; *.bmp; *.gif; *.tif; *.png)"
    sTemp = sTemp & ", *.jpg; *.bmp; *.gif; *.tif; *.png"
    strPath = Application.GetOpenFilename(sTemp)
    If strPath <> False Then
        For Each shtSheet In Worksheets
            shtSheet.Activate
            Range("A1").Select
            ActiveSheet.Pictures.Insert (strPath)
        Next shtSheet
        Set shtSheet = Nothing
    End If
End Sub

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (9205) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and 2021. You can find a version of this tip for the older menu interface of Excel here: Pasting a Graphic to Multiple Worksheets.