Using the Camera in VBA

In other issues of ExcelTips you learn about using the Camera tool to capture dynamic pictures of different parts of your worksheet. You may have been wondering how to use the same sort of feature from within VBA. The documentation on the issue is not terribly clear, but the following macro shows the general process:

Sub DoCamera()
    Dim MyPrompt As String
    Dim MyTitle As String
    Dim UserRange As Range
    Dim OutputRange As Range

    Application.ScreenUpdating = True

    'Prompt user for range to capture
    MyPrompt = "Select the range you would like to capture."
    MyTitle = "User Input Required"
    On Error Resume Next
    Set UserRange = Application.InputBox(Prompt:=MyPrompt, _
        Title:=MyTitle, Default:=ActiveCell.Address, Type:=8)
    If UserRange Is Nothing Then End
    On Error GoTo 0

    'Copy range to Clipboard as picture
    UserRange.CopyPicture

    'Prompt user for range to paste to
    MyPrompt = "Select the range on which you would like to paste."
    MyTitle = "User Input Required"
    On Error Resume Next
    Set OutputRange = Application.InputBox(Prompt:=MyPrompt, _
        Title:=MyTitle, Default:=ActiveCell.Address, Type:=8)
    If OutputRange Is Nothing Then End
    On Error GoTo 0

    'Paste picture to output range
    OutputRange.PasteSpecial
    Selection.Formula = UserRange.Address
End Sub

This macro prompts you to specify a range to be copied, it then copies it to the Clipboard as a picture, and prompts you for where to paste it. When pasted, the final line of the macro is the key to making the "photo" dynamic, just as is done manually with the Camera tool. The PasteSpecial command actually pastes the picture, and the pasted picture remains selected. Setting the Formula property for the selection (the picture) results in the dynamic nature of the graphic.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10521) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and 2021. You can find a version of this tip for the older menu interface of Excel here: Using the Camera in VBA.