Including Weeks in Elapsed Time

Many thanks J Woolly for the code below. Mine was presumably way too simple to cope with all the variations. I shall study the code and try to learn from it (as usual). My coding is all just hobby stuff so I really do appreciate the effort and kindness others go to to help me. Your name is familiar to me, so I've obviously used your coding sometime previous. Thanks again

@Barry
You might be interested in the TimeDif function in My Excel Toolbox:
=TimeDif(Start, Finish, [Approximate], [Conversational])
Start and Finish must be numeric or text dates and/or times. TimeDif returns the difference between Start and Finish as text, which can optionally be exact, approximate, or conversational.
See https://sites.google.com/view/MyExcelToolbox/
Here is a modified conversational version of TimeDif returning years, months, weeks, and days only (ignoring hours, minutes, and seconds) in the style of your function:

Function elapsInclWeeks2(Start As Date, Finish As Date) As String
    Dim dS As Date, dF As Date, dDif As Double, e As String
    Dim y As Long, m As Long, d As Long, w As Long
    Dim y1 As Long, m1 As Long, d1 As Long
    Dim y2 As Long, m2 As Long, d2 As Long
    dDif = Finish - Start
    d = Int(dDif): dS = Int(Start): dF = Int(Finish)
    'check if finish time-of-day is less than start time-of-day
    If (Finish - dF) < (Start - dS) Then dF = dF - 1
    d1 = Day(dS)
    d2 = Day(dF)
    m1 = Month(dS)
    m2 = Month(dF)
    y1 = Year(dS)
    y2 = Year(dF)
    If d2 < d1 Then 'finish day is less than start day
        m2 = m2 - 1
        If m2 = 0 Then m2 = 12: y2 = y2 - 1
        'add previous month's days
        d2 = d2 + Day(DateSerial(y2, (m2 + 1), 0))
    End If
    If d > d2 - d1 Then d = d2 - d1
    w = d \ 7
    d = d Mod 7
    If m2 < m1 Then 'finish month is less than start month
        y2 = y2 - 1
        'add previous year's months
        m2 = m2 + 12
    End If
    m = m2 - m1
    y = y2 - y1
    Dim s(True To False) As String: s(True) = "": s(False) = "s"
    If y Then e = y & " year" & s(y = 1)
    If m Then e = e & IIf(y, ", ", "") & m & " month" & s(m = 1)
    If w Then e = e & IIf(y Or m, ", ", "") & w & " week" & s(w = 1)
    If d Then e = e & IIf(y Or m Or w, ", ", "") & d & " day" & s(d = 1)
    If e = "" Then e = "0 days"
    elapsInclWeeks2 = e
End Function

With some of your dates, for example:
20-Jan-2007 to 08-Feb-2024, "17 years, 2 weeks, 5 days"
20-Jan-2007 to 30-Jan-2024, "17 years, 1 week, 3 days"
20-Jan-2007 to 27-Jan-2024, "17 years, 1 week"
01-Jan-2000 to 01-Oct-2000, "9 months"
01-Jan-2000 to 08-Oct-2000, "9 months, 1 week"
01-Jan-2000 to 31-Oct-2000, "9 months, 4 weeks, 2 days"

Including Weeks in Elapsed Time

In the earlier tip (T011360), Willy Vanhaelen added a VBA function to do the job for the Elapsed Time formula (for Y,M,D). That was helpful but resulting output was sometimes ‘weird’ as it produced negative portions as in:
Date1 = 20/01/2007; Date2 = 08/02/2024; Result =17 years, 1 month, -12 days.
I have tried to modify this AND include weeks in the result. However the output is still offering some ‘silly’ results:

Function elapsInclWeeks(a As Date, b As Date) As String
'Origin: Excel.Tips T011360 (Alan Wyatt)
'orig function: -- comments in above by Willy Vanhaelen--2016-06-10
Dim d As Integer, w As Integer, m As Integer, y As Integer
Dim s As String
Dim Mflag As Boolean: Mflag = False 'used to correct month value
Dim Yflag As Boolean: Yflag = False 'used to correct year value
'correction for negative output
If DatePart("d", b) <= DatePart("d", a) Then Mflag = True
If DatePart("m", b) = DatePart("m", a) Then Yflag = True
'calc years difference
y = DateDiff("yyyy", a, b)
If Yflag Then y = y - 1
'update value of a so that years match
a = DateAdd("yyyy", y, a)
'calc months difference
m = DateDiff("m", a, b)
If Mflag Then m = m - 1
'update value of a so that months match
a = DateAdd("m", m, a)
'calc weeks difference
w = Int(DateDiff("d", a, b) / 7)
'calc days difference
d = DateDiff("d", a, b) Mod 7
End Function

This ‘almost’ works but for the ‘silly’ output as in:
Date1 = 20/01/2007; Date2 = 30/01/2024; Result = 16 years, 12 months, 1 week, 3 days
Where the original formula* correctly gives: 17 years, 0 months, 1 week, 3 days
I have juggled but cannot spot the ‘error’

Also with start/end dates of:
Date1 = 01/01/2000; Date2 = 01/10/2000;
Function gives: 8 months, 4 weeks, 2 days.
Formula* gives: 9 months
Is this due to the way DateDiff() chops up the year depending on days in the month?

*the formula:
=DATEDIF($A$1,$B$1,"y") & " year(s), " & DATEDIF($A$1,$B$1,"ym")& " month(s), " & INT(DATEDIF($A$1,$B$1,"md")/7) & " week(s), "& MOD(DATEDIF($A$1,$B$1,"md"),7) & " day(s}."