Changing Ribbon Tool Defaults

The SetToolColor function in my first comment below assumes the Fill Color tool (Alt+H+H) looks like (see Figure 1 below) and the Font Color tool (Alt+H+F+C) looks like (see Figure 2 below) . In the first case, Standard Colors are 6 keystrokes down; in the second, they are down 7 keystrokes. If your version of Excel looks different, the SetToolColor function would require adjustment.

I like your approach.
Will try it soon.

If the VBA code in my previous comment is added to a standard module in Personal.xlsb, the following code will set default colors for the Home Ribbon's Fill Color and Font Color tools each time Excel is started. This code must be added to the ThisWorkbook module in Personal.xlsb.

Private WithEvents MyApp As Application 'process Application events
Private ToolDefaultsSet As Boolean

Private Sub Workbook_Open()
' Prepare to process Application events
' see http://www.cpearson.com/Excel/AppEvent.aspx
    Set MyApp = Application
End Sub

Private Sub MyApp_WorkbookOpen(ByVal WB As Workbook)
    If WB Is ThisWorkbook Then Exit Sub
    If Not ToolDefaultsSet Then
        SetToolDefaults
        ToolDefaultsSet = True
    End If
End Sub

Private Sub MyApp_NewWorkbook(ByVal WB As Workbook)
    If Not ToolDefaultsSet Then
        SetToolDefaults
        ToolDefaultsSet = True
    End If
End Sub

This code could be used with an Excel Add-in instead. For references to information about Personal.xlsb and Excel Add-in files, see https://sites.google.com/view/MyExcelToolbox/

The following SetToolDefaults macro will set default colors for the Fill Color and Font Color tools on the Home Ribbon. Once set, the new colors persist until changed by the user. (The Border tool default could also be set, but it will not persist; the keyboard shortcut for thick outside borders is Alt+H+B+T.)
This VBA code sets Fill Color to Green and Font Color to Blue. You can change those colors in the code to any of the Standard Colors DarkRed, Red, Orange, Yellow, LightGreen, Green, LightBlue, Blue, DarkBlue, or Purple.

Sub SetToolDefaults()
' Set persistent default Fill Color and Font Color tools on Home Ribbon
    'start in separate thread
    Application.OnTime Now, "SetToolDefaults_Do"
End Sub

Sub SetToolDefaults_Do(Optional Unlisted As Byte) 'removed from Macros list
' Set persistent default Fill Color and Font Color tools on Home Ribbon
' The Border tool can also be set, but it will not persist
' For example, thick outside border shortcut is Alt+H+B+T
' Standard Colors are DarkRed, Red, Orange, Yellow, LightGreen, Green,
' LightBlue, Blue, DarkBlue, and Purple
    Const FillColor As String = "Green"
    Const FontColor As String = "Blue"
    Dim sKeysFill As String, sKeysFont As String
    sKeysFill = SetToolColor("Fill", FillColor)
    sKeysFont = SetToolColor("Font", FontColor)
    'Ribbon must be visible but not pinned
    Dim Hidden As Boolean, Pinned As Boolean
    With Application
        .ScreenUpdating = False
        Hidden = (Not .CommandBars("Ribbon").Visible)
        If Hidden Then .ExecuteExcel4Macro "Show.ToolBar(""Ribbon"", True)"
        Pinned = (.CommandBars("Ribbon").Height > 100)
        If Pinned Then .CommandBars.ExecuteMso "MinimizeRibbon"
    End With
    'add temporary workbook
    Workbooks.Add
    'because Application.SendKeys is unreliable
    CreateObject("WScript.Shell").SendKeys sKeysFill & sKeysFont
    'finish in separate thread with adequate delay
    Const Delay As Double = 1 / 3600 / 24 'one second (adjust if necessary)
    With Application
        .OnTime (Now + Delay), _
            "'SetToolDefaults_Done " & Pinned & "," & Hidden & "'"
        .ScreenUpdating = True
    End With
End Sub

Sub SetToolDefaults_Done(Pinned As Boolean, Hidden As Boolean)
    'delete temporary workbook
    ActiveWorkbook.Close SaveChanges:=False
    'restore Ribbon
    With Application
        If Pinned Then .CommandBars.ExecuteMso "MinimizeRibbon"
        If Hidden Then .ExecuteExcel4Macro "Show.ToolBar(""Ribbon"", False)"
    End With
End Sub

Function SetToolColor(Tool As String, Color As String) As String
    Dim StandardColors As Variant, v As Variant, sHead As String
    Dim nDown As Integer, sDown As String
    Dim nRight As Integer, sRight As String
    Const myName As String = "SetToolColor"
    StandardColors = Array("DarkRed", "Red", "Orange", "Yellow", _
        "LightGreen", "Green", "LightBlue", "Blue", "DarkBlue", "Purple")
    For Each v In StandardColors
        v = LCase(v)
    Next v
    Select Case LCase(Tool)
        Case "fill": nDown = 6: sHead = "%hh"
        Case "font": nDown = 7: sHead = "%hfc"
        Case Else
            v = "Unrecognized tool " & Tool
            MsgBox v, vbCritical, myName
            Exit Function
    End Select
    With Application.WorksheetFunction
        sDown = .Rept("{DOWN}", nDown)
        On Error Resume Next
            nRight = .Match(LCase(Color), StandardColors, 0) - 1
            If Err Then
                v = "Standard Colors does not include " & Color
                MsgBox v, vbCritical, myName
                Exit Function
            End If
        On Error GoTo 0
        sRight = .Rept("{RIGHT}", nRight)
    End With
    SetToolColor = sHead & sDown & sRight & "~"
End Function