Printing Workbook Properties

When you are putting together a workbook, Excel tracks quite a bit of information that it collectively refers to as workbook properties. You can view the different properties maintained by displaying the Properties dialog box.

In Word you have the option to print document properties, if you desire. There is no intrinsic way to print workbook properties in Excel. Instead, you must resort to a macro that will place the names and values of the properties into a worksheet. You can then print the worksheet and have your workbook properties available in hardcopy format.

The following macro is an example of a good way to copy all the workbook properties to a worksheet that can be printed:

Public Sub WorkbookProperties()
    Dim p As DocumentProperty
    Dim iRow As Integer

    'Add new worksheet for info
    Worksheets.Add

    'Built in Properties
    iRow = 1
    Cells(iRow, 1).Value = "Built-in Properties"
    Cells(iRow, 1).Font.Bold = True
    iRow = iRow + 1
    Worksheets(1).Activate
    For Each p In ActiveWorkbook.BuiltinDocumentProperties
        On Error Resume Next
        Cells(iRow, 2).Value = p.Name
        'If no value then Excel causes an error so ignore!
        Cells(iRow, 3).Value = p.Value
        iRow = iRow + 1
    Next
    On Error GoTo 0

    'Custom Properties
    iRow = iRow + 1
    Cells(iRow, 1).Value = "Custom Properties"
    Cells(iRow, 1).Font.Bold = True
    iRow = iRow + 1
    For Each p In ActiveWorkbook.CustomDocumentProperties
        On Error Resume Next
        Cells(iRow, 2).Value = p.Name
        Cells(iRow, 3).Value = p.Value
        iRow = iRow + 1
    Next
    On Error GoTo 0
End Sub

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (9149) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, Excel in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Excel here: Printing Workbook Properties.