Getting Rid of 8-Bit ASCII Characters

Bill often has to import information into a worksheet so that he can process it for his company. In Bill's situation, one of the first steps he needs to do is to remove all the 8-bit ASCII characters that may be in the imported data. These characters don't need to be replaced with anything; they just need to be deleted so that only 7-bit ASCII characters remain. Bill wonders if there is an easy way to do this, perhaps with a macro of some type.

There are a few ways that you can approach this problem, depending on the characteristics of the data that you are starting with. Assuming that you only have 8-bit characters in your worksheet, then the only character codes that could be used for characters is 0 through 255. If you want to limit your data to only 7-bit characters, then that means you only want things in the character-code range of 0 through 127. Thus, you could use a macro to easily search for any characters in the range of 128 to 255 and simply delete them. This macro takes this approach:

Sub Remove8Bit1()
    Cells.Select
    For i = 128 To 255
        X = Chr(i)
        Selection.Replace What:=X, Replacement:="", _
          LookAt:=xlPart, SearchOrder:=xlByRows, _
          MatchCase:=False, SearchFormat:=False, _
          ReplaceFormat:=False
    Next
End Sub

The approach finds only those values in your worksheet that are in the 8-bit range. It won't touch anything that is in the 8-bit range that is actually created by a formula. (In most instances that shouldn't be a problem. If it is a problem, the proper fix is to modify the formulas creating the offending results.)

If your data contains Unicode characters, then you'll want to use a different approach. Technically, Unicode characters are not 8-bit characters; they are 16-bit characters and can have character code values in the range of 0 to 65,535. Because you want to ignore anything with a value over 127, using the search-based approach discussed earlier becomes unwieldy—you would end up doing over 65,000 searches instead of only 128.

A better approach is to simply look at all the characters in all the selected cells and if they have a character code over 127, ignore them. That is the approach taken in the following macro:

Sub Remove8Bit2()
    Dim rngCell As Range
    Dim intChar As Integer
    Dim strCheckString As String
    Dim strCheckChar As String
    Dim intCheckChar As Integer
    Dim strClean As String

    For Each rngCell In Selection
        strCheckString = rngCell.Value
        strClean = ""
        For intChar = 1 To Len(strCheckString)
            strCheckChar = Mid(strCheckString, intChar, 1)
            intCheckChar = Ascw(strCheckChar)
            If intCheckChar < 128 Then
                strClean = strClean & strCheckChar
            End If
        Next intChar
        rngCell.Value = strClean
    Next rngCell
End Sub

Note that the macro uses the Ascw function instead of the traditional Asc function so that it looks at Unicode values.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10565) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, and Excel in Microsoft 365. You can find a version of this tip for the older menu interface of Excel here: Getting Rid of 8-Bit ASCII Characters.