Getting a Conditional Count of Cells Containing Values

Written by Allen Wyatt (last updated October 22, 2022)
This tip applies to Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365


The formula =SUMIF(B1:B100,"Current",D1:D100) provides the sum of the values in column D, provided the corresponding cell in column B contains the text "Current". What Kenneth actually needs, though, is a count of the values in column D when column B contains "Current". (The count of values in D may well be different than the number of instances of "Current" in B.) He wishes it was as simple as changing SUMIF to COUNTIF, but that produces an error.

The reason the error occurs is because SUMIF requires three parameters and COUNTIF requires only two. Thus, if you simply replace SUMIF with COUNTIF, then you'll get an error. Instead, you could use COUNTIF in this way:

=COUNTIF(B1:B100,"Current")

This will not give you an error, but it also won't give you a correct answer. Kenneth wants a count of the number of cells containing values in the range D1:D100, but only if the corresponding cell in column B contains the text "Current." The COUNTIF formula doesn't even take column D into effect; it only counts the number of cells in the range B1:B100 that contain the word "Current."

The solution is to use the COUNTIFS function, instead. This function allows you to check multiple conditions in order to derive a count. In this case, the following version would work:

=COUNTIFS(B1:B100,"current",D1:D100,">0")

This formula counts the number of values in D1:D100 that are greater than zero. (Well, it also only counts them if B1:B100 contains "current.") This works because empty cells or cells that contain text are considered by COUNTIFS to be equivalent to 0. Note, as well, that the function is case-insensitive when it comes to matching: "current" will also match "Current" or any combination of uppercase and lowercase letters in the word.

If your cells might contain negative values, then you should try this variation, instead:

=COUNTIFS(B1:B100,"current",D1:D100,"<>")

The drawback is that this method also includes in the count any cells that contain text.

You could also use the following formula:

=SUMPRODUCT(--(B1:B100="current"),--(D1:D100<>""))

Again, this one includes text values in the count. If you want to ignore the text values, then this variation works great:

=SUMPRODUCT(--(B1:B100="current"),--ISNUMBER(D1:D100))

The following formula can also be used, provided you enter it as an array formula (press Ctrl+Shift+Enter):

=SUM((B1:B100="current")*ISNUMBER(D1:D100))

There are also other ways you could derive the total you need. One method would be to use the DCOUNT function (which counts based upon multiple criteria), but that approach requires more setup than the formulas already described.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (13433) applies to Microsoft Excel 2007, 2010, 2013, 2016, 2019, 2021, and Excel in Microsoft 365.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Unwanted Cover Pages with Print Jobs

When you print a document, do you get more than you bargained for? If you get extra pages printed either before or within ...

Discover More

Non-standard Sorting

Information in a cell can be entered using line feeds, which results in multiple lines of data in the same cell. If you ...

Discover More

Cell and Name References in COUNTIF

The second parameter of the COUNTIF function is used to specify the criteria to be used when determining what should be ...

Discover More

Dive Deep into Macros! Make Excel do things you thought were impossible, discover techniques you won't find anywhere else, and create powerful automated reports. Bill Jelen and Tracy Syrstad help you instantly visualize information to make it actionable. You’ll find step-by-step instructions, real-world case studies, and 50 workbooks packed with examples and solutions. Check out Microsoft Excel 2019 VBA and Macros today!

More ExcelTips (ribbon)

Generating Double-Digit Random Numbers

Normally you use the RAND and RANDBETWEEN functions to generate random numbers. What if you want to generate random ...

Discover More

Activating the Formula Bar with the Keyboard

Hate to take your hands off the keyboard while working on a worksheet? Here's one way to activate the Formula Bar without ...

Discover More

Starting Out Formulas

When you enter a formula from the keyboard, Excel only knows it is a formula if you start it with an equal sign. You can ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] (all 7 characters, in the sequence shown) in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is seven more than 2?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Excel that uses the ribbon interface (Excel 2007 or later)? This site is for you! If you use an earlier version of Excel, visit our ExcelTips site focusing on the menu interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.